blob: 4f03087da5331dce84a7277c89e41b2338e1c139 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# $Id: PKGBUILD 138644 2011-09-27 13:37:54Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=totem
pkgname=('totem' 'totem-plugin')
pkgver=3.2.0
pkgrel=1
pkgdesc="A GNOME3 integrated movie player based on Gstreamer."
url="http://www.gnome.org"
arch=('i686' 'x86_64')
license=('GPL2' 'custom')
depends=('gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins' 'totem-plparser' 'libxxf86vm'
'libxtst' 'desktop-file-utils' 'iso-codes' 'python2' 'libpeas' 'hicolor-icon-theme'
'gnome-icon-theme-symbolic' 'gsettings-desktop-schemas' 'dconf' 'clutter-gst'
'clutter-gtk' 'mx')
makedepends=('intltool' 'gtk-doc' 'python2-gobject' 'nautilus' 'libgdata' 'xulrunner' 'lirc-utils'
'libepc' 'bluez' 'vala' 'grilo')
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgbase}/${pkgver%.*}/${pkgbase}-${pkgver}.tar.xz)
sha256sums=('97277b6746bdbfa7de185fa20602bfb5c72b77169f346311001d4013a93f9139')
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/totem \
--localstatedir=/var \
--disable-static \
--enable-python \
--enable-nautilus
make
}
package_totem() {
groups=('gnome-extra')
install=totem.install
optdepends=('gstreamer0.10-ugly-plugins: Extra media codecs'
'gstreamer0.10-bad-plugins: Extra media codecs'
'gstreamer0.10-ffmpeg: Extra media codecs'
'lirc-utils: Infrared Remote Control plugin'
'libepc: Publish Playlist plugin'
'libgdata: YouTube Browser plugin'
'bluez: Bemused plugin'
'grilo-plugins: Browse sidebar (remote media)')
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -r "${pkgdir}/usr/lib/mozilla"
rm "${pkgdir}/usr/lib/totem/totem-plugin-viewer"
sed -i "s|#!/usr/bin/python$|#!/usr/bin/python2|" \
$pkgdir/usr/lib/totem/{totem/totem-bugreport.py,plugins/iplayer/iplayer2.py}
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/totem/COPYING"
}
package_totem-plugin() {
pkgdesc="Totem mozilla/firefox plugin"
depends=("totem=${pkgver}")
cd "${srcdir}/${pkgbase}-${pkgver}"
make -C browser-plugin \
plugindir=/usr/lib/mozilla/plugins \
xptdir=/usr/lib/mozilla/plugins \
DESTDIR="${pkgdir}" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/totem-plugin/COPYING"
}
|
