blob: e6649d29901f112b30614a3c4ac1de4c08c53fa5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# $Id: PKGBUILD 167895 2012-10-03 15:58:28Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgbase=totem
pkgname=('totem' 'totem-plugin')
pkgver=3.6.0
pkgrel=1
pkgdesc="GNOME3 movie player based on GStreamer"
url="http://www.gnome.org"
arch=(i686 x86_64)
license=(GPL2 custom)
depends=(gst-plugins-base gst-plugins-good totem-plparser desktop-file-utils iso-codes libpeas
hicolor-icon-theme gnome-icon-theme-symbolic gsettings-desktop-schemas dconf clutter-gst
clutter-gtk mx python2-gobject gst-plugins-bad)
makedepends=(intltool gnome-doc-utils nautilus lirc-utils vala grilo pylint)
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgbase/${pkgver%.*}/$pkgbase-$pkgver.tar.xz
browser-plugins.ini)
sha256sums=('e767da34f5212bd9b2d3ea9bc7e3a87b284581ee012214274225dd8decb8fe3e'
'a50a3bbf35f0535f7e8e20af1893446a2e5711015484f9ae6d1ff91af3b23c4e')
build() {
cd "$pkgbase-$pkgver"
./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/totem \
--localstatedir=/var \
--disable-static \
--enable-python \
--enable-nautilus
make
}
package_totem() {
groups=(gnome-extra)
install=totem.install
optdepends=('gst-plugins-ugly: Extra media codecs'
'gst-ffmpeg: Extra media codecs'
'lirc-utils: Infrared Remote Control plugin'
'grilo-plugins: Browse sidebar (remote media)'
'pyxdg: opensubtitles plugin')
cd "$pkgbase-$pkgver"
make DESTDIR="${pkgdir}" install
rm -r "$pkgdir/usr/lib/mozilla"
rm "$pkgdir/usr/lib/totem/totem-plugin-viewer"
sed -i "s|#!/usr/bin/python$|#!/usr/bin/python2|" \
$pkgdir/usr/lib/totem/totem/totem-bugreport.py
install -Dm644 COPYING "$pkgdir/usr/share/licenses/totem/COPYING"
}
package_totem-plugin() {
pkgdesc="Totem plugin for web browsers"
depends=("totem=$pkgver")
backup=(etc/totem/browser-plugins.ini)
cd "$pkgbase-$pkgver"
make -C browser-plugin \
plugindir=/usr/lib/mozilla/plugins \
xptdir=/usr/lib/mozilla/plugins \
DESTDIR="$pkgdir" install
install -Dm644 ../browser-plugins.ini "$pkgdir/etc/totem/browser-plugins.ini"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/totem-plugin/COPYING"
}
|
