kde-unstable/kdebindings-qtruby/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# $Id: PKGBUILD 171725 2012-11-21 18:17:05Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgname=kdebindings-qtruby
pkgver=4.9.80
pkgrel=1
pkgdesc="Ruby bindings for the Qt libraries"
url="https://projects.kde.org/projects/kde/kdebindings/ruby/qtruby"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kdebindings')
depends=('kdebindings-smokeqt' 'ruby')
makedepends=('cmake' 'automoc4' 'kdebindings-smokegen')
conflicts=('kdebindings-ruby')
source=("http://download.kde.org/unstable/${pkgver}/src/qtruby-${pkgver}.tar.xz")
sha1sums=('02f2e194105c5e3fbc4181d0969c0c59a76f241b')

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../qtruby-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCUSTOM_RUBY_SITE_LIB_DIR=$(ruby -e 'puts RbConfig::CONFIG["vendorlibdir"]') \
    -DCUSTOM_RUBY_SITE_ARCH_DIR=$(ruby -e 'puts RbConfig::CONFIG["vendorarchdir"]')
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
}