blob: cba123fab095b60d80ccb1ef4e06eb3eaaaf345e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# $Id: PKGBUILD 171713 2012-11-21 18:08:37Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
pkgname=nepomuk-core
pkgver=4.9.80
pkgrel=1
pkgdesc="Contains the central Nepomuk services like file indexing, file system monitoring, query, storage, client libraries"
url="https://projects.kde.org/projects/kde/kdelibs/nepomuk-core"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('kdelibs' 'poppler-qt' 'taglib' 'ffmpeg')
makedepends=('cmake' 'automoc4' 'doxygen')
source=("http://download.kde.org/unstable/${pkgver}/src/${pkgname}-${pkgver}.tar.xz")
sha1sums=('c296a0e4a601d7f0afece4a27cdbcc220692c4f7')
build() {
mkdir build
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd "${srcdir}"/build
make DESTDIR="${pkgdir}" install
# Fix the python shebang
sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
"${pkgdir}"/usr/bin/nepomuk-simpleresource-rcgen
}
|
