blob: d14fe148fe12cfddd154c0a1e3031bd120c9b940 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id$
#Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
#Contributor: BlackEagle <ike.devolder@gmail.com>
#Contributor: Dany Martineau <dany.luc.martineau@gmail.com>
#Maintainer (Parabola): André Silva <emulatorman@lavabit.com>
#Contributor (Parabola): Kete <kete@ninthfloor.org>
_pkgname=clementine
pkgname=clementine-libre
pkgver=1.1.1
pkgrel=1.1
pkgdesc="A music player and library organizer, without spotify support"
url="http://www.clementine-player.org/"
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('gstreamer0.10-base' 'taglib' 'glew' 'liblastfm' 'libgpod'
'libmtp' 'libplist' 'hicolor-icon-theme' 'qt' 'libimobiledevice'
'qjson' 'libcdio' 'protobuf' 'qca' 'qca-ossl' 'gvfs')
makedepends=('cmake' 'boost' 'mesa')
optdepends=('gstreamer0.10-base-plugins: for more open formats'
'gstreamer0.10-good-plugins: for use with "Good" plugin libraries'
'gstreamer0.10-bad-libre-plugins: for use with "Bad" plugin libraries'
'gstreamer0.10-ugly-plugins: for use with "Ugly" plugin libraries')
replaces=('clementine')
conflicts=('clementine')
provides=("clementine=$pkgver")
source=(http://clementine-player.googlecode.com/files/${_pkgname}-${pkgver}.tar.gz
remove-and-disable-spotify.patch)
sha1sums=('f8d3e9c8f54ac488323ab5a629c9accbe256378e'
'4d336b6a42100a268e4d905b9596453f396fb649')
install=clementine.install
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
# Remove nonfree spotify references on files
patch -Np1 -i ../remove-and-disable-spotify.patch
# Remove nonfree spotifyblob folders
rm -rv ext/{clementine-spotifyblob,libclementine-spotifyblob}
# Remove nonfree spotify files
rm -v cmake/SpotifyVersion.cmake
rm -v data/icons/svg/spotify.svg
rm -v data/schema/schema-30.sql
rm -v src/{globalsearch/spotifysearchprovider.{cpp,h},internet/spotify{blobdownloader.{cpp,h},server.{cpp,h},service.{cpp,h},settingspage.{cpp,h,ui}}}
# Create a blank file due that is a dependency for clementine
touch data/schema/schema-30.sql
cmake . -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
