summaryrefslogtreecommitdiff
path: root/libre/dvdrtools-libre/PKGBUILD
blob: cf5ce1f4d101297fd9783df35853ac646dd950d9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# $Id: PKGBUILD 78820 2012-10-25 06:47:28Z foutrelis $
# Maintainer: Alexander Baldeck <alexander@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=dvdrtools
pkgname=dvdrtools-libre
pkgver=0.3.1
pkgrel=3.2
pkgdesc="A fork of cdrtools, with the primary goal of supporting writable DVD drives, without nonfree apple_driver utility"
arch=('i686' 'x86_64' 'mips64el')
url="http://savannah.nongnu.org/projects/dvdrtools/"
license=('GPL2')
depends=('file' 'bash')
makedepends=('transcode')
optdepends=('transcode: video/DVD ripper and encoder for the terminal/console')
provides=("$_pkgname=$pkgver" 'cdrkit')
conflicts=("$_pkgname" 'cdrkit')
replaces=("$_pkgname")
source=(ftp://ftp.archlinux.org/other/dvdrtools/$_pkgname-$pkgver.tar.gz)
md5sums=('5707b7e877b853e258cd738938833006')

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"

  # Remove nonfree apple_driver utility
  rm -rvf {mkisofs/README.hfs_boot,apple_driver{.8,.c,.mk,_man.mk}}
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  ./configure --prefix=/usr --mandir=/usr/share/man
  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  # Make symlinks for cdrtools compatibility
  ln -s dvdrecord $pkgdir/usr/bin/cdrecord
  ln -s dvdrecord $pkgdir/usr/bin/wodim
  ln -s mkisofs   $pkgdir/usr/bin/genisoimage
  ln -s mkisofs   $pkgdir/usr/bin/mkhybrid
  ln -s readcd    $pkgdir/usr/bin/readom

  ln -s dvdrecord.1.gz $pkgdir/usr/share/man/man1/cdrecord.1.gz
  ln -s dvdrecord.1.gz $pkgdir/usr/share/man/man1/wodim.1.gz
  ln -s mkisofs.8.gz   $pkgdir/usr/share/man/man8/genisoimage.8.gz
  ln -s mkisofs.8.gz   $pkgdir/usr/share/man/man8/mkhybrid.8.gz
  ln -s readcd.1.gz    $pkgdir/usr/share/man/man1/readom.1.gz
}