blob: 3ef5c65eeb1736a1da13793276cc113ddfcf6a87 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# $Id$
# Maintainer (Parabola): fauno <fauno@kiwwwi.com.ar>
# Contributor (Parabola): André Silva <andre.paulista@adinet.com.uy>
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
_pkgname=mplayer-vaapi
pkgname=mplayer-vaapi-libre
pkgver=34578
pkgrel=5.1
pkgdesc="A movie player, compiled with vaapi support"
arch=('i686' 'x86_64')
url="http://gitorious.org/vaapi/mplayer"
license=('GPL')
depends=('libxxf86dga' 'libxxf86vm' 'libmad' 'libcdio' 'libxinerama' 'sdl-libre'
'lame' 'fontconfig' 'libtheora' 'xvidcore' 'libmng' 'libxss' 'mesa'
'smbclient' 'aalib' 'jack' 'libcaca' 'x264' 'speex' 'faad2'
'lirc-utils' 'ttf-dejavu' 'libxvmc' 'enca' 'opencore-amr' 'libdca'
'a52dec' 'schroedinger' 'mpg123' 'libvpx' 'libpulse' 'fribidi' 'faad2'
'libva' 'libass' 'desktop-file-utils')
makedepends=('unzip-libre' 'live-media' 'yasm' 'ladspa' 'git')
provides=("$_pkgname=$pkgver" "mplayer=$pkgver")
conflicts=('mplayer' "$_pkgname")
replaces=('mplayer-vaapi')
backup=('etc/mplayer/codecs.conf' 'etc/mplayer/input.conf')
source=(http://pkgbuild.com/~foutrelis/mplayer-vaapi-$pkgver.tar.xz
tweak-desktop-file.patch
mplayer.png
live-media.patch)
options=('!buildflags' '!emptydirs')
install=mplayer-vaapi.install
sha256sums=('cc35a057c8a64d2cdec2dc0a037811ef0f91dd03cd3d07465c7272a08665a37d'
'5b39f0a61969bf330c4434cb17975101be93c27334f65e154e4a93033033e795'
'061739a8cc267748ad58f168034cc39785d949a5262772535e1b347c7842af48'
'9c1400f27dd2ea54c125c66ed1af0eab19761b1b2ae808fa491cd3732fd8a685')
build() {
cd "$srcdir/mplayer-vaapi-$pkgver"
patch -d etc -Np0 -i "$srcdir/tweak-desktop-file.patch"
patch -Np0 -i "$srcdir/live-media.patch"
./configure --prefix=/usr \
--enable-runtime-cpudetection \
--disable-gui \
--disable-arts \
--disable-liblzo \
--enable-speex \
--disable-cdparanoia \
--disable-openal \
--disable-libdv \
--disable-musepack \
--disable-esd \
--disable-mga \
--disable-ass-internal \
--disable-faac \
--enable-xvmc \
--disable-vdpau \
--enable-vaapi \
--language=all \
--confdir=/etc/mplayer
[[ $CARCH == i686 ]] && sed -i 's|-march=i486|-march=i686|g' config.mak
make
}
package() {
cd "$srcdir/mplayer-vaapi-$pkgver"
make -j1 DESTDIR="$pkgdir" install-mplayer install-mplayer-man
install -Dm644 etc/{codecs.conf,input.conf,example.conf} "$pkgdir/etc/mplayer/"
install -Dm644 etc/mplayer.desktop "$pkgdir/usr/share/applications/mplayer.desktop"
install -d "$pkgdir/usr/share/mplayer/"
ln -s /usr/share/fonts/TTF/DejaVuSans.ttf "$pkgdir/usr/share/mplayer/subfont.ttf"
rm -rf "$pkgdir/usr/share/mplayer/font"
install -Dm644 "$srcdir/mplayer.png" "$pkgdir/usr/share/pixmaps/mplayer.png"
}
# vim:set ts=2 sw=2 et:
|
