blob: a517b2722b2c16d8de6393ed1e9c20c518375694 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 89167 2013-04-27 12:41:00Z ioni $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
_pkgbasename=gdk-pixbuf2
pkgname=lib32-$_pkgbasename
pkgver=2.28.1
pkgrel=2
pkgdesc="An image loading library (32-bit)"
arch=('x86_64')
url="http://www.gtk.org/"
license=('LGPL2')
depends=(lib32-glib2 lib32-libpng lib32-libtiff lib32-libjpeg lib32-libx11
$_pkgbasename)
makedepends=(gcc-multilib)
options=('!libtool' '!docs')
install=gdk-pixbuf2.install
source=(http://download.gnome.org/sources/gdk-pixbuf/${pkgver%.*}/gdk-pixbuf-${pkgver}.tar.xz)
sha256sums=('bea0b743fdb5c3c8e23210f73623ec5f18f9ead2522942897fe739d80b50c2bb')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd "${srcdir}/gdk-pixbuf-${pkgver}"
./configure --prefix=/usr --libdir=/usr/lib32 \
--without-libjasper \
--with-x11 \
--with-included-loaders=png
make
}
package() {
cd "${srcdir}/gdk-pixbuf-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/etc
rm -rf "${pkgdir}"/usr/{include,share}
cd "${pkgdir}"/usr/bin
mv gdk-pixbuf-query-loaders gdk-pixbuf-query-loaders-32
rm gdk-pixbuf-pixdata
rm gdk-pixbuf-csource
}
# vim:set ts=2 sw=2 et:
|
