blob: aeb1cbc80ca45704adb57ddbc1ee276867f53ffd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 66417 2012-02-24 16:16:14Z dreisner $
# Maintainer: judd <jvinet@zeroflux.org>
_pkgbasename=util-linux
pkgname=lib32-$_pkgbasename
pkgver=2.21
pkgrel=1
pkgdesc="Miscellaneous system utilities for Linux (32-bit)"
url='http://www.kernel.org/pub/linux/utils/util-linux/'
arch=('x86_64')
depends=('lib32-glibc' "$_pkgbasename")
makedepends=('gcc-multilib')
provides=('lib32-util-linux-ng')
conflicts=('lib32-util-linux-ng')
replaces=('lib32-util-linux-ng')
license=('GPL2')
options=('!libtool' '!emptydirs')
source=("ftp://ftp.kernel.org/pub/linux/utils/util-linux/v2.21/util-linux-$pkgver.tar.xz")
md5sums=('208aa058f4117759d2939d1be7d662fc')
shopt -s extglob
build() {
cd "$srcdir/$_pkgbasename-$pkgver"
export CC="gcc -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
./autogen.sh
./configure --without-ncurses --libdir=/usr/lib32
for lib in lib{mount,blkid,uuid}; do
make -C "$lib"
done
}
package() {
cd "$srcdir/$_pkgbasename-$pkgver"
make DESTDIR="$pkgdir" install
# remove everything but libs
rm -rf "$pkgdir"/!(usr) "$pkgdir"/usr/!(lib32)
}
|
