blob: 264a417501ab6343600c152e675f867c1fd3b0d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 60201 2011-12-07 14:41:34Z arodseth $
# Maintainer: Florian Pritz <flo@xssn.at>
_pkgbasename=curl
pkgname=lib32-$_pkgbasename
pkgver=7.21.7
pkgrel=1
pkgdesc="An URL retrieval utility and library (32-bit)"
arch=('x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('lib32-zlib' 'lib32-openssl' 'bash' 'ca-certificates' 'lib32-libssh2' $_pkgbasename)
makedepends=(gcc-multilib)
options=('!libtool')
source=("http://curl.haxx.se/download/${_pkgbasename}-${pkgver}.tar.bz2")
md5sums=('5f6d50c4d4ee38c57fe37e3cff75adbd')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${srcdir}/${_pkgbasename}-${pkgver}
./configure \
--with-random=/dev/urandom \
--prefix=/usr \
--mandir=/usr/share/man \
--disable-dependency-tracking \
--enable-ipv6 \
--disable-ldaps \
--disable-ldap \
--disable-manual \
--enable-versioned-symbols \
--with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
--without-libidn \
--libdir=/usr/lib32 \
--enable-threaded-resolver
make
}
package() {
cd ${srcdir}/${_pkgbasename}-${pkgver}
make DESTDIR=${pkgdir} install
rm -rf "${pkgdir}"/usr/{share,bin}
#we need curlbuild.h
find ${pkgdir}/usr/include/curl -type f -not -name curlbuild.h -delete
#now save it as curlbuild-32.h
mv ${pkgdir}/usr/include/curl/curlbuild.h ${pkgdir}/usr/include/curl/curlbuild-32.h
mkdir -p "$pkgdir/usr/share/licenses"
ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
|
