blob: cff3d6d901e85aa8dc3d5241207896eda3d5186b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 26527 2010-09-15 22:30:16Z bluewind $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
pkgname=lib32-dbus-core
_pkgbasename=dbus-core
pkgver=1.4.0
pkgrel=2
pkgdesc="Freedesktop.org message bus system (32-bit)"
arch=('x86_64' 'mips64el')
url="http://www.freedesktop.org/Software/dbus"
license=('GPL' 'custom')
depends=('lib32-glibc' 'lib32-expat' 'dbus-core')
makedepends=('gcc-multilib')
options=(!libtool)
source=(http://dbus.freedesktop.org/releases/dbus/dbus-${pkgver}.tar.gz)
md5sums=('f59618b18d2fb2bd1fce9e1c5a2a3282')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd "${srcdir}/dbus-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libdir=/usr/lib32 \
--libexecdir=/usr/lib/dbus-1.0 --with-dbus-user=81 \
--with-system-pid-file=/var/run/dbus.pid \
--enable-inotify --disable-dnotify \
--disable-verbose-mode --disable-static \
--disable-tests --disable-asserts --without-x
make
}
package() {
cd "${srcdir}/dbus-${pkgver}"
make DESTDIR=${pkgdir} install
rm -rf "${pkgdir}"/usr/{bin,include,lib,share}
rm -rf "${pkgdir}"/{etc,var}
mkdir -p "${pkgdir}/usr/share/licenses"
ln -s ${_pkgbasename} "${pkgdir}/usr/share/licenses/${pkgname}"
}
|
