blob: 5aeb0f1bc96eaedfdccb4a82af5edde4ec954b30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 91063 2010-09-21 19:21:24Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
_pkgbasename=gdk-pixbuf2
pkgname=lib32-$_pkgbasename
pkgver=2.23.3
pkgrel=1
pkgdesc="An image loading library for gtk2 (32-bit)"
arch=('i686' 'x86_64')
url="http://www.gtk.org/"
license=('GPL2')
depends=('lib32-glib2>=2.25.15'
lib32-lib{'png>=1.4.3','tiff>=3.9.4','jpeg>=8.0.2',x11}
$_pkgbasename)
makedepends=(gcc-multilib)
options=('!libtool' '!docs')
install=gdk-pixbuf2.install
source=(http://download.gnome.org/sources/gdk-pixbuf/2.23/gdk-pixbuf-${pkgver}.tar.bz2)
sha256sums=('9faba780151c02e13cb2029d512c975e9c41b98cd72de6d2cc50e4af10a5e76a')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd "${srcdir}/gdk-pixbuf-${pkgver}"
./configure --prefix=/usr --libdir=/usr/lib32 \
--without-libjasper \
--with-included-loaders=png
make
}
package() {
cd "${srcdir}/gdk-pixbuf-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/etc
rm -rf "${pkgdir}"/usr/{include,share}
cd "${pkgdir}"/usr/bin
mv gdk-pixbuf-query-loaders gdk-pixbuf-query-loaders-32
rm gdk-pixbuf-csource
}
# vim:set ts=2 sw=2 et:
|
