blob: 6f92a26b17695b5f495f227189b35536be4e61ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Baptiste Daroussin <baptiste.daroussin@gmail.com>
# Contributor: Grigorios Bouzakis <grbzks[at]gmail[dot]com>
# Contributor: mightyjaym <jm.ambrosino@free.fr>
_pkgbasename=giflib
pkgname=lib32-$_pkgbasename
pkgver=4.1.6
pkgrel=6
pkgdesc="A library for reading and writing gif images (32-bit)"
url="http://sourceforge.net/projects/giflib/"
arch=('x86_64')
license=('MIT')
depends=('lib32-libx11' 'lib32-libsm' $_pkgbasename)
makedepends=(gcc-multilib)
provides=("lib32-libungif=${pkgver}")
conflicts=('lib32-libungif')
replaces=('lib32-libungif')
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/giflib/${_pkgbasename}-${pkgver}.tar.bz2)
md5sums=('7125644155ae6ad33dbc9fc15a14735f')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${srcdir}/${_pkgbasename}-${pkgver}
./configure --prefix=/usr --libdir=/usr/lib32
make
}
package() {
cd ${srcdir}/${_pkgbasename}-${pkgver}
make DESTDIR=${pkgdir} install
# libungif compatibility - instructions taken from Redhat specfile
MAJOR=`echo ${pkgver} | sed 's/\([0-9]\+\)\..*/\1/'`
gcc -shared -Wl,-soname,libungif.so.${MAJOR} -Llib/.libs -lgif -o libungif.so.${pkgver}
install -m755 libungif.so.${pkgver} ${pkgdir}/usr/lib32/
ln -sf libungif.so.${pkgver} ${pkgdir}/usr/lib32/libungif.so.4
ln -sf libungif.so.4 ${pkgdir}/usr/lib32/libungif.so
rm -rf "${pkgdir}"/usr/{include,share,bin}
install -m755 -d ${pkgdir}/usr/share/licenses
ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
|
