blob: d178f7bb3149323abd4bf87bd07199185105231b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 39076 2011-02-06 10:56:39Z ibiru $
# Contributor: Jan de Groot <jgc@archlinux.org>
_pkgbasename=libdrm
pkgname=lib32-$_pkgbasename
pkgver=2.4.23
pkgrel=1
pkgdesc="Userspace interface to kernel DRM services (32-bit)"
arch=(x86_64)
license=('custom')
depends=('lib32-glibc' $_pkgbasename)
makedepends=(gcc-multilib)
options=('!libtool')
url="http://dri.freedesktop.org/"
source=(http://dri.freedesktop.org/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.bz2
no-pthread-stubs.patch)
md5sums=('7577ff36ec364d88fae466d4f7fc5fc6'
'9b5ec3bbebe86921e2057694c42f65b8')
build() {
cd "${srcdir}/${_pkgbasename}-${pkgver}"
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
patch -Np1 -i "${srcdir}/no-pthread-stubs.patch"
libtoolize --force
aclocal
autoconf
automake
./configure --prefix=/usr --libdir=/usr/lib32 \
--enable-intel --enable-radeon \
--enable-vmwgfx-experimental-api --enable-nouveau-experimental-api \
--enable-udev
make
}
package() {
cd "${srcdir}/${_pkgbasename}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/{include,share,bin}
mkdir -p "$pkgdir/usr/share/licenses"
ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
|
