blob: ce944c1634e06b7ad2b99f6fc7f54dee3658c838 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 66918 2012-03-01 15:51:48Z bluewind $
# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
_pkgbasename=sdl
pkgname=lib32-$_pkgbasename
pkgver=1.2.15
pkgrel=2
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (32-bit)"
arch=('x86_64')
url="http://www.libsdl.org"
license=('LGPL')
depends=('lib32-libxext' 'lib32-libxrender' 'lib32-libx11' $_pkgbasename)
makedepends=('lib32-alsa-lib' 'lib32-mesa' 'lib32-libpulse' gcc-multilib)
options=('!libtool')
source=(http://www.libsdl.org/release/SDL-${pkgver}.tar.gz
sdl-1.2.14-fix-mouse-clicking.patch)
md5sums=('9d96df8417572a2afb781a7c4c811a85'
'04d8c179f125e04bcd4c9d60e013c2d7')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${srcdir}/SDL-${pkgver}
patch -Np1 -i $srcdir/sdl-1.2.14-fix-mouse-clicking.patch
./configure --prefix=/usr --disable-nasm --enable-alsa \
--with-x --disable-rpath --libdir=/usr/lib32 --disable-static
make
}
package() {
cd ${srcdir}/SDL-${pkgver}
make DESTDIR=${pkgdir} install
rm -rf "${pkgdir}"/usr/{include,share}
cd "$pkgdir/usr/bin"
mv sdl-config sdl-config-32
}
|
