blob: a72223ae335910fade62d49dcff8e870c93d9059 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 35298 2010-12-18 01:45:49Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
_pkgbasename=zlib
pkgname=lib32-$_pkgbasename
pkgver=1.2.5
pkgrel=6
pkgdesc='Compression library implementing the deflate compression method found in gzip and PKZIP (32-bit)'
arch=('x86_64')
license=('custom')
url="http://www.zlib.net/"
depends=('lib32-glibc' $_pkgbasename)
makedepends=(gcc-multilib)
options=('!makeflags')
source=("http://zlib.net/zlib-${pkgver}.tar.gz"
'zlib-1.2.5-lfs-decls.patch')
md5sums=('c735eab2d659a96e5a594c9e8541ad63'
'4cb279ea3beab621f3526bf7b7ab99e5')
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${srcdir}/zlib-$pkgver
# see http://bugs.archlinux.org/task/19280
patch -p1 -i ${srcdir}/zlib-1.2.5-lfs-decls.patch
# work around gcc bug; see https://bugs.archlinux.org/task/20647
export CFLAGS="${CFLAGS/-O2/-O3} -fno-tree-vectorize -DUNALIGNED_OK"
./configure --prefix=/usr \
--libdir=/usr/lib32
make
make check
}
package() {
cd ${srcdir}/zlib-$pkgver
make install DESTDIR=${pkgdir}
rm -rf "${pkgdir}"/usr/{include,share,bin}
mkdir -p "$pkgdir/usr/share/licenses"
ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
|
