blob: 79163db90fad3f2da395c6d0a99bdbf9b0fc3495 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 105458 2014-02-08 15:39:04Z bgyorgy $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Aaron Schaefer <aaron@elasticdog.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
_pkgname=duplicity
pkgname=duplicity-nonprism
pkgver=0.6.23
pkgrel=3
pkgdesc='A utility for encrypted, bandwidth-efficient backups using the rsync algorithm, without python2-gdata recommendation'
arch=('i686' 'x86_64')
url='http://www.nongnu.org/duplicity/'
license=('GPL')
depends=('gnupg' 'librsync' 'ncftp' 'python2-paramiko' 'python2-lockfile')
optdepends=('lftp: FTPS backend'
'python2-boto: Amazon S3 backend'
'python2-gobject: GIO backend'
'gvfs: GIO backend'
'python2-httplib2: Ubuntu One backend'
'python2-oauthlib: Ubuntu One backend'
'rsync: rsync backend')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://savannah.nongnu.org/download/$_pkgname/$_pkgname-$pkgver.tar.gz"{,.sig}
"gpg-encode.patch")
md5sums=('ae0e84446bcf114735de1057ed53c977'
'SKIP'
'366555c73aeebf7f15f6f37ec65176ce')
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver}"
# Fix gpg encrypted backup (FS#38838, upstream revision 961, will be fixed in 0.6.24).
patch -Np0 -i ../gpg-encode.patch
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
# python2 fix
for file in $(find . -name '*.py' -print); do
sed -i 's_^#!.*/usr/bin/python$_#!/usr/bin/python2_' $file
sed -i 's_^#!.*/usr/bin/env.*python$_#!/usr/bin/env python2_' $file
done
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
python2 setup.py install --root="$pkgdir" --optimize=1
# fix broken documentation permissions until upstream does (FS#27301)
chmod 644 "$pkgdir/usr/share/man/man1/$_pkgname.1"
chmod 644 "$pkgdir/usr/share/man/man1/rdiffdir.1"
chmod 644 "$pkgdir/usr/share/doc/$_pkgname-$pkgver"/*
}
|
