blob: 2aa501159de5b96d1369d19f7a23791e1eb59cbf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Jorge Araya Navarro <jorgean@lavabit.com>
# Maintainer (aur): Bjoern Bidar <theodorstormgrade@gmail.com>
pkgname='ryzom-hg'
_hgver=923522b
pkgver=20131215
pkgrel=3
pkgdesc="An awesome free software 3D MMORPG game"
arch=('i686' 'x86_64')
url="http://www.ryzom.com/"
license=('AGPL3')
depends=('curl' 'hicolor-icon-theme' 'libvorbis' 'libjpeg' 'libwww-hg' 'luabind' 'ryzom-data')
conflicts=('ryzom')
makedepends=('mercurial' 'cpptest' 'cmake' 'bison' 'freealut' 'rrdtool' 'boost' 'freetype2')
source=("libre://$pkgname-$pkgver.tar.gz")
mksource=(".$pkgname-$pkgver::hg+https://bitbucket.org/ryzom/ryzomcore#revision=${_hgver}")
mksource() {
rm -rf "$srcdir/$pkgname-$pkgver"
cp -a "$srcdir/.$pkgname-$pkgver/code" "${srcdir}/${pkgname}-${pkgver}"
# some patching required...
sed -i 's|<freetype/|<freetype2/|g' "${srcdir}/${pkgname}-${pkgver}/nel/src/3d/font_generator.cpp"
}
build() {
mkdir -p "$srcdir/build"
cd "$srcdir/build"
cmake -Wno-dev "$srcdir/${pkgname}-${pkgver}" -DFINAL_VERSION=ON -DWITH_STATIC=OFF -DWITH_NEL_TOOLS=OFF -DWITH_NEL_TESTS=OFF -DWITH_LUA51=ON -DWITH_NEL_SAMPLES=OFF -DWITH_RYZOM_TOOLS=OFF -DWITH_RYZOM_SERVER=OFF -DWITH_RYZOM_CLIENT=ON -DWITH_NEL=ON -DWITH_DRIVER_OPENGL=ON -DWITH_DRIVER_OPENAL=ON -DCMAKE_INSTALL_PREFIX=/usr -DRYZOM_ETC_PREFIX=/etc/ryzom -DRYZOM_SHARE_PREFIX=/usr/share/ryzom -DRYZOM_BIN_PREFIX=/usr/bin -DRYZOM_GAMES_PREFIX=/usr/bin -DFREETYPE_INCLUDE_DIRS="/usr/include;/usr/include/freetype2"
make all
}
package() {
cd "$srcdir/build"
make DESTDIR="$pkgdir" install
cd "$pkgdir/etc/ryzom/"
# instead of the open shard, we point to the actual ryzom shard.
# this cannot be on prepare(), I tried that already and didn't work
sed -i 's|"ryzom_open"|"ryzom_live"|g' client_default.cfg
sed -i 's|PatchServer = "";|PatchServer = "http://dl.ryzom.com/patch_live";|g' client_default.cfg
sed -i 's|SignUpURL = "";|SignUpURL = "http://www.ryzom.com/subscribe";|g' client_default.cfg
sed -i 's|"open.ryzom.com:40916";|"shard.ryzom.com:40916";|g' client_default.cfg
sed -i 's|CreateAccountURL = "";|CreateAccountURL = "https://secure.ryzom.com/signup/from_client.php";|g' client_default.cfg
sed -i 's|InstallWebPage = "";|InstallWebPage = "http://dl.ryzom.com/installer/";|g' client_default.cfg
sed -i 's|"http://open.ryzom.com:50000/stats/stats.php";|"http://shard.ryzom.com:50000/stats/stats.php";|g' client_default.cfg
sed -i 's|atys.|app.|g' client_default.cfg
sed -i 's|"app.ryzom.com" |"api.ryzom.com", "app.ryzom.com" |g' client_default.cfg
}
mksha256sums=('SKIP')
sha256sums=('187e9a508be4c3c07f768fc98497941ac4946caf2202d24311aac81d73cff5a5')
|
