blob: 9bade16e0d91dba8763809745fc9f134c6318dbf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 141633 2011-11-01 00:51:56Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=gegl
pkgver=0.1.6
pkgrel=2
pkgdesc="Graph based image processing framework"
arch=('i686' 'x86_64')
url="http://www.gegl.org/"
license=('GPL3' 'LGPL3')
depends=('babl' 'gtk2')
makedepends=('ruby' 'lua' 'openexr' 'ffmpeg' 'librsvg' 'jasper' 'exiv2')
optdepends=('openexr: for using the openexr plugin' \
'ffmpeg: for using the ffmpeg plugin' \
'librsvg: for using the svg plugin' \
'jasper: for using the jasper plugin')
options=('!libtool')
source=(ftp://ftp.gimp.org/pub/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2 \
0.1.6-ffmpeg.patch)
sha1sums=('27bedcfd077da7a6913b82966dbec904b22c121d'
'd62d4987f1c0fc256f5968271fc65cce0cc4c195')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i "${srcdir}/0.1.6-ffmpeg.patch"
./configure --prefix=/usr --with-sdl --with-openexr --with-librsvg \
--with-libavformat --with-jasper --disable-docs
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
