blob: ecf6dd54982c783cbf89446c9ee9251e767e1bbe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# $Id: PKGBUILD 163025 2012-07-05 23:25:55Z dreisner $
# Contributor: FUBAR <mrfubar@gmail.com>
# Contributor: simo <simo@archlinux.org>
# Contributor: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Maintainer: Dave Reisner <dreisner@archlinux.org>
pkgname=bitlbee
pkgver=3.0.5
pkgrel=4
pkgdesc='Brings instant messaging (XMPP, MSN, Yahoo!, AIM, ICQ, Twitter) to IRC'
url='http://www.bitlbee.org/'
license=('GPL')
arch=('i686' 'x86_64')
depends=('openssl' 'glib2')
makedepends=('asciidoc' 'libotr')
optdepends=('skype4py: to use skyped'
'libotr: for OTR encryption support'
'xinetd: to run bitlbee through xinetd')
source=("http://get.bitlbee.org/src/${pkgname}-${pkgver}.tar.gz"
'sbindir.patch'
'xinetd'
'rc.d'
'bitlbee.tmpfiles')
sha1sums=('74afdff87be49ce060771a6ae10d7643cd57b9b6'
'9b774e6d85471a4e43e25b8b941cd0e1032a7a6c'
'5e0af27ba9cc4fe455e3381c75fc49a9326e2f17'
'02423c500ac64f673ba26a3395c7c7036c17343e'
'3695ed2fe22436c4d0fc3ead829f7d1f89bc491c')
backup=('etc/bitlbee/bitlbee.conf'
'etc/bitlbee/motd.txt'
'etc/xinetd.d/bitlbee')
install=bitlbee.install
build() {
cd "$pkgname-$pkgver"
patch -p1 -i ../sbindir.patch
./configure \
--prefix=/usr \
--etcdir=/etc/bitlbee \
--pidfile=/run/bitlbee/bitlbee.pid \
--ipcsocket=/run/bitlbee/bitlbee.sock \
--systemdsystemunitdir=/usr/lib/systemd/system \
--ssl=openssl \
--strip=0 \
--otr=plugin \
--skype=plugin
make
}
package() {
make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev}
install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
install -Dm644 "$srcdir/xinetd" "$pkgdir/etc/xinetd.d/bitlbee"
install -Dm755 "$srcdir/rc.d" "$pkgdir/etc/rc.d/bitlbee"
install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
}
|
