blob: 6210e7418c89272aa6a42ce866c8e99275fab07e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 141489 2011-10-30 23:10:21Z thomas $
# Maintainer: Thomas Bächler <thomas@archlinux.org>
pkgname=cryptsetup
pkgver=1.4.0
pkgrel=1
pkgdesc="Userspace setup tool for transparent encryption of block devices using dm-crypt"
arch=(i686 x86_64)
license=('GPL')
url="http://code.google.com/p/cryptsetup/"
groups=('base')
depends=('device-mapper>=2.02.85-2' 'libgcrypt' 'popt')
conflicts=('mkinitcpio<0.7')
options=('!libtool' '!emptydirs')
source=(http://cryptsetup.googlecode.com/files/${pkgname}-${pkgver}.tar.bz2
encrypt_hook
encrypt_install)
sha256sums=('96d682853c8019cfeae0b21250cd2d00af42e46251807e8dbda2ff8427c2e9ed'
'811bbea1337106ad811731c746d73ee81039bad00aef52398e3a377ad0766757'
'd4380195351b70abf8fcb3cd19461879c55a7a07e4915d1f0365b295b112a573')
build() {
cd $srcdir/$pkgname-${pkgver}
./configure --prefix=/usr --disable-static --sbindir=/sbin --libdir=/lib
make
}
package() {
cd $srcdir/$pkgname-${pkgver}
make DESTDIR=$pkgdir install
# install hook
install -D -m644 $srcdir/encrypt_hook $pkgdir/lib/initcpio/hooks/encrypt
install -D -m644 $srcdir/encrypt_install $pkgdir/lib/initcpio/install/encrypt
# Fix pkgconfig location
install -d -m755 $pkgdir/usr/lib
mv $pkgdir/lib/pkgconfig $pkgdir/usr/lib/
}
|
