blob: 4b96ec8f3503712985739c3ccf0e1626d0d0ed29 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# $Id: PKGBUILD 164380 2012-07-31 20:34:32Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Tom Killian <tom.archlinux.org>
# Contributor: Judd Vinet <jvinet.zeroflux.org>
pkgname=dhcpcd
pkgver=5.6.0
pkgrel=1
pkgdesc="RFC2131 compliant DHCP client daemon"
url="http://roy.marples.name/projects/dhcpcd/"
arch=('i686' 'x86_64')
license=('BSD')
groups=('base')
depends=('glibc' 'sh')
backup=('etc/conf.d/dhcpcd' 'etc/dhcpcd.conf')
options=('emptydirs') # We Need the Empty /var/lib/dhcpcd Directory
source=("http://roy.marples.name/downloads/$pkgname/$pkgname-$pkgver.tar.bz2" \
'dhcpcd.conf.d' 'dhcpcd.service')
sha1sums=('28ad6931393420a72da307ee173466a9e00cd952'
'b67b9ce6a2faaca75fea356966a16be2283b7db0'
'3d0542eab1b89a88d56ca427128228ac72c40d1f')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
# configure variables
./configure --libexecdir=/usr/lib/dhcpcd --dbdir=/var/lib/dhcpcd \
--rundir=/run
# Build
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
# Create Binary Symlink
install -d ${pkgdir}/usr/sbin
ln -sf /sbin/dhcpcd ${pkgdir}/usr/sbin/dhcpcd
# Install Configuration File used in /etc/rc.d/network
install -D -m644 ../dhcpcd.conf.d $pkgdir/etc/conf.d/$pkgname
# Install License
install -d $pkgdir/usr/share/licenses/$pkgname
awk '{if(FNR<27)print $0}' ${srcdir}/${pkgname}-${pkgver}/configure.h \
>> ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
# Set Options in /etc/dhcpcd.conf
echo noipv4ll >> ${pkgdir}/etc/dhcpcd.conf # Disable ip4vall
# install systemd files
install -Dm644 ${srcdir}/dhcpcd.service ${pkgdir}/usr/lib/systemd/system/dhcpcd@.service
}
|
