blob: af0262d65261ffb7bf8d8d4e10b0d01f23b43a08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 163057 2012-07-06 15:21:11Z ibiru $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
pkgname=gegl
pkgver=0.2.0
pkgrel=2
pkgdesc="Graph based image processing framework"
arch=('i686' 'x86_64')
url="http://www.gegl.org/"
license=('GPL3' 'LGPL3')
depends=('babl' 'gtk2')
makedepends=('intltool' 'ruby' 'lua' 'openexr' 'ffmpeg' 'librsvg' 'jasper' 'exiv2')
optdepends=('openexr: for using the openexr plugin' \
'ffmpeg: for using the ffmpeg plugin' \
'librsvg: for using the svg plugin' \
'jasper: for using the jasper plugin')
options=('!libtool')
source=(ftp://ftp.gimp.org/pub/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha1sums=('764cc66cb3c7b261b8fc18a6268a0e264a91d573')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --with-sdl --with-openexr --with-librsvg \
--with-libavformat --with-jasper --disable-docs
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make check
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
