blob: cdd9c242f29dfd80dd68e8d8b96cb6bd09d6147a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 159845 2012-05-27 07:42:23Z bluewind $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Sarah Hay <sarah@archlinux.org>
pkgname=gtk2-perl
pkgver=1.244
pkgrel=1
pkgdesc="Perl bindings for GTK+ 2.x"
arch=(i686 x86_64)
license=('LGPL')
url="http://gtk2-perl.sourceforge.net/"
makedepends=('perl-extutils-pkgconfig' 'perl-extutils-depends')
depends=('gtk2' 'pango-perl')
checkdepends=('ttf-dejavu' 'xorg-server-xvfb')
options=('!emptydirs')
source=(http://downloads.sourceforge.net/sourceforge/gtk2-perl/Gtk2-${pkgver}.tar.gz)
md5sums=('191fda807f44a7c82d699838bf544bca')
build() {
cd "${srcdir}/Gtk2-${pkgver}"
PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
make
}
check() {
cd "${srcdir}/Gtk2-${pkgver}"
LD_PRELOAD="" Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 :99 &
LD_PRELOAD="" DISPLAY=:99 make test
kill $!
}
package() {
cd "${srcdir}/Gtk2-${pkgver}"
make install DESTDIR="${pkgdir}"
}
|
