blob: 218fa0cd3af161df287121386639222901ce3813 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 165083 2012-08-10 05:02:43Z eric $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
pkgbase=libofx
pkgname=('libofx' 'libofx-doc')
pkgver=0.9.5
pkgrel=1
pkgdesc="API for the OFX banking standard"
arch=('i686' 'x86_64')
url="http://libofx.sourceforge.net"
license=('GPL')
depends=('opensp' 'curl' 'libxml++')
checkdepends=('gnupg')
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz libofx-gcc47.patch)
sha1sums=('7e5245d68a0f3f7efad2fd809b2afbbff6ba0e73'
'6c327e24543cb8ba901bfb204343a85c68264654')
build() {
cd "$srcdir/$pkgbase-$pkgver"
patch -p1 -i "$srcdir/libofx-gcc47.patch"
./configure --prefix=/usr
make
}
check() {
cd "$srcdir/$pkgbase-$pkgver"
make check
}
package_libofx() {
options=('!libtool' '!docs')
cd "$srcdir/$pkgbase-$pkgver"
make DESTDIR="$pkgdir" install
}
package_libofx-doc() {
pkgdesc="Documention of the OFX banking standard API"
depends=()
cd "$srcdir/$pkgbase-$pkgver"
make DESTDIR="$pkgdir" install-docDATA
make -C doc DESTDIR="$pkgdir" install
}
|
