blob: 9e2a3a8cd37e73d152004729da9516576502ee0f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 166764 2012-09-18 18:20:39Z andyrtr $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Sergej Pupykin <sergej@aur.archlinux.org>
pkgname=man-db
pkgver=2.6.3
pkgrel=1
pkgdesc="A utility for reading man pages"
arch=('i686' 'x86_64')
url="http://www.nongnu.org/man-db/"
license=('GPL' 'LGPL')
groups=('base')
depends=( 'bash' 'gdbm' 'zlib' 'groff' 'libpipeline')
optdepends=('less' 'gzip')
backup=('etc/man_db.conf'
'etc/cron.daily/man-db')
conflicts=('man')
provides=('man')
replaces=('man')
install=${pkgname}.install
source=(http://savannah.nongnu.org/download/man-db/$pkgname-$pkgver.tar.xz{,.sig}
convert-mans man-db.cron.daily)
options=('!libtool')
md5sums=('a593a095599ae97bcacf8d038659a146'
'64975c20b1a6453f9b860ff7f916bcf1'
'2b7662a7d5b33fe91f9f3e034361a2f6'
'd30c39ae47560304471b5461719e0f03')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib \
--with-db=gdbm --disable-setuid --enable-mandirs=GNU \
--with-sections="1 n l 8 3 0 2 5 4 9 6 7"
make
}
check() {
cd ${srcdir}/${pkgname}-${pkgver}
make check
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
# part of groff pkg
rm -f ${pkgdir}/usr/bin/zsoelim
# script from LFS to convert manpages, see
# http://www.linuxfromscratch.org/lfs/view/6.4/chapter06/man-db.html
install -D -m755 ${srcdir}/convert-mans ${pkgdir}/usr/bin/convert-mans
#install whatis cron script
install -D -m744 ${srcdir}/man-db.cron.daily ${pkgdir}/etc/cron.daily/man-db
}
|
