blob: 13d711cc9306bacafb3b74fef036a120c547da30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 163063 2012-07-06 15:21:51Z ibiru $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=moc
pkgver=20120224
pkgrel=2
pkgdesc="An ncurses console audio player with support for the mp3, ogg, and wave formats"
arch=('i686' 'x86_64')
url="http://moc.daper.net/"
license=('GPL')
depends=('libmad' 'libid3tag' 'jack' 'curl' 'libltdl' 'file')
makedepends=('speex' 'ffmpeg' 'taglib' 'libmpcdec' 'wavpack' 'libmodplug')
optdepends=('speex: for using the speex plugin'
'ffmpeg: for using the ffmpeg plugin'
'taglib: for using the musepack plugin'
'libmpcdec: for using the musepack plugin'
'wavpack: for using the wavpack plugin'
'libmodplug: for using the modplug plugin')
options=('!libtool')
source=(ftp://ftp.archlinux.org/other/moc/${pkgname}-${pkgver}.tar.xz{,.sig})
sha1sums=('8ad3521d99fe6f2514907088c70e50c84ec09b46'
'e8b2396d99692b0c4f85971d3fa6f5aecb1eb9d3')
# source PKGBUILD && mksource
mksource() {
[[ -x /usr/bin/svn ]] || (echo "svn not found. Install subversion." && return 1)
_svnver=2412
_svntrunk="svn://daper.net/moc/trunk"
_svnmod="${pkgname}-${pkgver}"
mkdir ${pkgname}-${pkgver}
pushd ${pkgname}-${pkgver}
svn co ${_svntrunk} --config-dir ./ -r ${_svnver} ${_svnmod}
find . -depth -type d -name .svn -exec rm -rf {} \;
tar -cJf ../${pkgname}-${pkgver}.tar.xz ${pkgname}-${pkgver}/*
popd
rm -r ${pkgname}-${pkgver}
gpg --detach-sign --use-agent -u ${GPGKEY} ${pkgname}-${pkgver}.tar.xz
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Disabling aac to use the external ffmpeg to play them (FS#13164)
autoreconf -i
./configure --prefix=/usr --without-rcc --without-aac \
--with-oss --with-alsa --with-jack --with-mp3 \
--with-musepack --with-vorbis --with-flac --with-wavpack \
--with-sndfile --with-modplug --with-ffmpeg --with-speex \
--with-samplerate --with-curl --disable-debug
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
