blob: ef8e56403723d51a57391495b51bf46d1c988422 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 152748 2012-03-09 13:54:49Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: damir <damir@archlinux.org>
pkgname=mpfr
_pkgver=3.1.0
_patchlevel=p7
pkgver=${_pkgver}.${_patchlevel}
pkgrel=1
pkgdesc="Multiple-precision floating-point library"
arch=('i686' 'x86_64')
url="http://www.mpfr.org/"
license=('LGPL')
depends=('gmp>=5.0')
options=('!libtool')
install=mpfr.install
source=(http://www.mpfr.org/mpfr-current/mpfr-${_pkgver}.tar.xz{,.asc}
mpfr-${_pkgver}.${_patchlevel}.patch)
md5sums=('6e495841bb026481567006cec0f821c3'
'293374ee4b01527f8f7889fdfa9016f8'
'fb1bf603a2ad5e6ecc1903c3c53f5e13')
build() {
cd "${srcdir}/${pkgname}-${_pkgver}"
patch -Np1 -i $srcdir/mpfr-${_pkgver}.${_patchlevel}.patch
./configure --prefix=/usr --enable-thread-safe --enable-shared
make
}
check() {
cd "${srcdir}/${pkgname}-${_pkgver}"
make check
}
package() {
cd "${srcdir}/${pkgname}-${_pkgver}"
make DESTDIR="${pkgdir}" install
}
|
