blob: 70bb6e4d8902932364356fed8745cca58257ec8d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 169160 2012-10-18 19:22:54Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=polkit
pkgver=0.107
pkgrel=4
pkgdesc="Application development toolkit for controlling system-wide privileges"
arch=(i686 x86_64)
license=('LGPL')
url="http://www.freedesktop.org/wiki/Software/PolicyKit"
depends=('glib2' 'pam' 'expat' 'libsystemd' 'js')
makedepends=('intltool' 'gtk-doc' 'gobject-introspection')
replaces=('policykit')
options=('!libtool')
install=polkit.install
source=(http://www.freedesktop.org/software/polkit/releases/$pkgname-$pkgver.tar.gz
polkit.pam fix-empty-wheel.patch)
md5sums=('0e4f9c53f43fd1b25ac3f0d2e09b2ae1'
'6564f95878297b954f0572bc1610dd15'
'c99ab2a7919ad0b69fde4804c043b07f')
build() {
cd $pkgname-$pkgver
# https://bugs.archlinux.org/task/31717
patch -Np1 -i ../fix-empty-wheel.patch
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --libexecdir=/usr/lib/polkit-1 \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--disable-static --enable-gtk-doc
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
chown 102 "$pkgdir/etc/polkit-1/rules.d"
chown 102 "$pkgdir/usr/share/polkit-1/rules.d"
install -m644 "$srcdir/polkit.pam" "$pkgdir/etc/pam.d/polkit-1"
}
|
