blob: a029b0cfaf320e00bda13b99172ef3748b844d85 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 148301 2012-01-30 18:50:32Z ibiru $
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: Ben <ben@benmazer.net>
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=scribus
pkgver=1.4.0
pkgrel=2
pkgdesc="A desktop publishing program"
arch=('i686' 'x86_64')
url="http://www.scribus.net"
license=('GPL')
install=scribus.install
depends=('libcups>=1.3.11' 'lcms>=1.18' 'qt' 'ghostscript>=8.70' \
'libart-lgpl>=2.3.20' 'python2' 'libxml2>=2.7.3' 'cairo' \
'desktop-file-utils' 'shared-mime-info')
makedepends=('cmake')
options=(!libtool)
source=(http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz)
md5sums=('ae19e62399941fb8e868d8e762caf494')
sha1sums=('0e3afb98a56084c2938a8402df2d89214c42b809')
build() {
cd "${srcdir}"
sed -i -e 's|#!/usr/bin/python|#!/usr/bin/python2|' \
-e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
${pkgname}-${pkgver}/scribus/plugins/scriptplugin/{samples,scripts}/*
mkdir build
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON \
-DWANT_CAIRO=1 \
-DLIB_SUFFIX=""
make
}
package() {
cd "${srcdir}/build"
make DESTDIR="${pkgdir}" install
# fix icon path in .desktop file
sed -i 's|Icon=scribus|Icon=/usr/share/scribus/icons/scribus.png|' \
"${srcdir}/${pkgname}-${pkgver}/scribus.desktop"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/scribus.desktop" \
"${pkgdir}/usr/share/applications/scribus.desktop"
}
|
