blob: a999277f142a21dd730645220abd5be4adb1fde8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 134206 2011-08-02 14:26:49Z ibiru $
# Maintainer: Thomas Bächler <thomas@archlinux.org>
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
pkgname=syslinux
pkgver=4.04
pkgrel=2
arch=('i686' 'x86_64')
pkgdesc="Collection of boot loaders that boot from FAT, ext2/3/4 and btrfs filesystems, from CDs and via PXE"
url="http://syslinux.zytor.com/"
license=('GPL2')
depends=('perl' 'glibc')
optdepends=('perl-passwd-md5: For md5pass'
'perl-digest-sha1: For sha1pass'
'mtools: For mkdiskimage and syslinux'
)
makedepends=('nasm')
backup=('boot/syslinux/syslinux.cfg')
install=syslinux.install
source=(http://www.kernel.org/pub/linux/utils/boot/syslinux/$pkgname-${pkgver}.tar.bz2
syslinux-dont-build-dos-windows-targets.patch
syslinux.cfg
syslinux-install_update)
md5sums=('a3936208767eb7ced65320abe2e33a10'
'5274062f91931eae6573f1ec3cd5b640'
'4dc27d8ab3802f8e50f3dda28168ce6d'
'b5b4953c0a5a01cd16441402f6321765')
build() {
# Do not try to build syslinux with our default LDFLAGS, it will fail
unset LDFLAGS
cd "$srcdir"/$pkgname-${pkgver}
# Do not try to build the Windows or DOS installers
patch -p1 -i "$srcdir"/syslinux-dont-build-dos-windows-targets.patch
# Fix FHS manpage path
sed 's|/usr/man|/usr/share/man|g' -i MCONFIG
make
}
package() {
cd "$srcdir"/$pkgname-${pkgver}
make INSTALLROOT="$pkgdir" AUXDIR=/usr/lib/syslinux install
# Install the default configuration
install -D -m644 "$srcdir"/syslinux.cfg "$pkgdir"/boot/syslinux/syslinux.cfg
# Install the installation and update script
# This script is maintained at git://gist.github.com/772138.git
install -D -m755 "$srcdir"/syslinux-install_update "$pkgdir"/usr/sbin/syslinux-install_update
}
|
