blob: 3a25d87e4aff6d7e256a8decfe278ee62f62deec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 123085 2011-05-08 03:28:44Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Maintainer: Aaron Griffin <aaron@archlinux.org>
pkgname=syslog-ng
pkgver=3.2.4
pkgrel=1
pkgdesc="Next-generation syslogd with advanced networking and filtering capabilities"
arch=('i686' 'x86_64')
license=('GPL2')
groups=('base')
url="http://www.balabit.com/network-security/syslog-ng/"
depends=('glib2' 'eventlog' 'tcp_wrappers' 'openssl' 'libcap' 'awk')
makedepends=('flex' 'pkg-config')
optdepends=('logrotate: for rotating log files')
provides=('logger')
options=('!libtool')
backup=('etc/syslog-ng/modules.conf' 'etc/syslog-ng/scl.conf' \
'etc/syslog-ng/syslog-ng.conf' 'etc/logrotate.d/syslog-ng')
source=(http://www.balabit.com/downloads/files/syslog-ng/sources/${pkgver}/source/${pkgname}_${pkgver}.tar.gz \
syslog-ng.conf syslog-ng.logrotate syslog-ng.rc cap_syslog.patch)
md5sums=('5995f7dad0053a478b60a63f6f754203'
'344dddfff946300f5576b13a7e8ea19f'
'735636090be4582885974542d2a75855'
'8b4441343d859c2f01c2cf799a7e6f98'
'46e5dcff71f820d497898331a3f608fe')
sha1sums=('ff732f7223bd2bd0424d4b9028b523cf62133af1'
'b9eb8c61f7cccda543fc5c97fe1d40a8d15e713f'
'ac997b25d7d8e69e66782d3771a0e12aff55ae7f'
'4481819762fd1b6f25903016a8878e63c0058fcb'
'f093a09626a528d23f0f2aeece018cab15a735a9')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# fix #22555 for kernels >=2.6.38
patch -p1 -i ../cap_syslog.patch
./configure --prefix=/usr --sysconfdir=/etc/syslog-ng \
--libexecdir=/usr/lib --localstatedir=/var/lib/syslog-ng \
--enable-tcp-wrapper \
--with-pidfile-dir=/var/run \
--disable-spoof-source
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -dm755 "${pkgdir}/var/lib/syslog-ng" "${pkgdir}/etc/syslog-ng/patterndb.d"
install -Dm644 "${srcdir}/syslog-ng.conf" "${pkgdir}/etc/syslog-ng/syslog-ng.conf"
install -Dm644 "${srcdir}/syslog-ng.logrotate" "${pkgdir}/etc/logrotate.d/syslog-ng"
install -Dm755 "${srcdir}/syslog-ng.rc" "${pkgdir}/etc/rc.d/syslog-ng"
}
|
