blob: 01dbce661bafe92b74a26d6c947f91f4b6c68173 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 140602 2011-10-17 12:30:38Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=vte3
pkgname=(vte3 vte-common)
pkgver=0.30.1
pkgrel=1
pkgdesc="Virtual Terminal Emulator widget for use with GTK3"
arch=('i686' 'x86_64')
license=('LGPL')
options=('!libtool' '!emptydirs')
makedepends=('intltool' 'gobject-introspection' 'gtk3')
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/GNOME/sources/vte/0.30/vte-${pkgver}.tar.xz)
sha256sums=('bbe421de3015935c22f685eea0eb8be2c1fecd5021c1f822996b8f0a282f6b64')
build() {
cd "${srcdir}/vte-${pkgver}"
#warning: type-punning to incomplete type might break strict-aliasing rules
export CFLAGS="$CFLAGS -fno-strict-aliasing"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/vte \
--localstatedir=/var --disable-static \
--enable-introspection
make
}
package_vte3(){
depends=('gtk3' 'vte-common')
cd "${srcdir}/vte-${pkgver}"
make DESTDIR="${pkgdir}" install
rm "${pkgdir}"/usr/lib/vte/gnome-pty-helper
}
package_vte-common() {
pkgdesc="Common files used by vte and vte3"
cd "${srcdir}/vte-${pkgver}"
make -C gnome-pty-helper DESTDIR="${pkgdir}" install
}
|
