Sun Feb 19 23:15:25 UTC 2012

1 files changed, 56 insertions, 0 deletions

diff --git a/community-staging/deadbeef/PKGBUILD b/community-staging/deadbeef/PKGBUILD
new file mode 100644
index 000000000..2c470fcf7
--- /dev/null
+++ b/community-staging/deadbeef/PKGBUILD
@@ -0,0 +1,56 @@
+# $Id: PKGBUILD 64836 2012-02-18 16:07:27Z lfleischer $
+# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
+# Contributor: Alexey Yakovenko <waker@users.sourceforge.net>
+
+pkgname=deadbeef
+pkgver=0.5.1
+pkgrel=5
+pkgdesc='An audio player for GNU/Linux based on GTK2.'
+arch=('i686' 'x86_64')
+url='http://deadbeef.sourceforge.net'
+license=('GPL2')
+depends=('gtk2' 'alsa-lib' 'hicolor-icon-theme' 'desktop-file-utils')
+makedepends=('libvorbis' 'libmad' 'flac' 'curl' 'imlib2' 'wavpack' 'libsndfile' 'libcdio' 'libcddb'
+             'ffmpeg' 'libx11' 'faad2' 'zlib' 'intltool' 'pkgconfig' 'libpulse' 'libzip'
+             'libsamplerate')
+optdepends=('libsamplerate: for Resampler plugin'
+            'libvorbis: for Ogg Vorbis playback'
+            'libmad: for MP1/MP2/MP3 playback'
+            'flac: for FLAC playback'
+            'curl: for Last.fm scrobbler, SHOUTcast, Icecast, Podcast support'
+            'imlib2: for artwork plugin'
+            'wavpack: for WavPack playback'
+            'libsndfile: for Wave playback'
+            'libcdio: audio cd plugin'
+            'libcddb: audio cd plugin'
+            'ffmpeg: for WMA, AA, OMA, AC, etc.'
+            'faad2: for AAC/MP4 support'
+            'dbus: for OSD notifications support'
+            'pulseaudio: for PulseAudio output plugin'
+            'libx11: for global hotkeys plugin'
+            'zlib: for Audio Overload plugin'
+            'libzip: for vfs_zip plugin')
+options=('!libtool')
+install='deadbeef.install'
+source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
+        'deadbeef-0.5.1-ffmpeg-AV_VERSION_INT.patch'
+        'deadbeef-0.5.1-ffmpeg-version-check-fix.patch')
+md5sums=('be8359d1bd9cf7679cf2ca748996e726'
+         'd1c913c0ccefef33012732cf0ae49f7f'
+         '6d22855f61f4d2fea4b343dca76d5e85')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  patch -Np1 -i ../deadbeef-0.5.1-ffmpeg-AV_VERSION_INT.patch
+  patch -Np1 -i ../deadbeef-0.5.1-ffmpeg-version-check-fix.patch
+
+  ./configure --prefix=/usr
+  make
+}
+
+package () {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  make prefix="${pkgdir}/usr" install
+}