Wed Mar 7 00:01:25 UTC 2012

1 files changed, 46 insertions, 0 deletions

diff --git a/community/0ad/PKGBUILD b/community/0ad/PKGBUILD
new file mode 100644
index 000000000..8a84fc0e9
--- /dev/null
+++ b/community/0ad/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
+# Contributor: t3ddy  <t3ddy1988 "at" gmail {dot} com>
+# Contributor: Adrián Chaves Fernández (Gallaecio) <adriyetichaves@gmail.com>
+pkgname=0ad
+pkgver=a8
+_pkgver=r10803-alpha
+pkgrel=1
+pkgdesc="Cross-platform, 3D and historically-based real-time strategy game"
+arch=('i686' 'x86_64')
+url="http://wildfiregames.com/0ad"
+license=('GPL2' 'CCPL')
+depends=('binutils' 'boost-libs' 'curl' 'enet>=1.3' 'gamin' 'libogg' 'libpng' 'libvorbis' 'libxml2' 'openal' 'openexr' 'python2' 'sdl' 'wxgtk' 'zip' 'zlib' 'libgl' '0ad-data')
+makedepends=('boost' 'cmake' 'mesa')
+source=("http://releases.wildfiregames.com/$pkgname-$_pkgver-unix-build.tar.xz")
+md5sums=('92ac750c433a8aea4db602019b27a274')
+
+build() {
+  cd "$srcdir/$pkgname-$_pkgver/build/workspaces"
+
+  sed -i 's/unix_names = { "boost_signals-mt", "boost_filesystem-mt", "boost_system-mt" },/unix_names = { "boost_signals", "boost_filesystem", "boost_system" },/g' "${srcdir}/${pkgname}-${_pkgver}/build/premake/extern_libs4.lua"
+
+  # next version use this
+  # sed -i 's/unix_names = { "boost_filesystem-mt", "boost_system-mt" },/unix_names = { "boost_filesystem", "boost_system" },/g' "${srcdir}/${pkgname}-${_pkgver}/build/premake/extern_libs4.lua"
+  # sed -i 's/unix_names = { "boost_signals-mt" },/unix_names = { "boost_signals" },/g' "${srcdir}/${pkgname}-${_pkgver}/build/premake/extern_libs4.lua"
+
+
+  ./update-workspaces.sh \
+      --with-system-enet \
+      --bindir=/usr/bin \
+      --libdir=/usr/lib \
+      --datadir=/usr/share/${pkgname}/data
+
+  cd "$srcdir/$pkgname-$_pkgver/build/workspaces/gcc"
+
+  make CONFIG=Release
+}
+
+package() {
+  install -d ${pkgdir}/usr/{bin,lib}
+  install -Dm755 ${srcdir}/${pkgname}-${_pkgver}/binaries/system/pyrogenesis ${pkgdir}/usr/bin
+  install -Dm755 ${srcdir}/${pkgname}-${_pkgver}/binaries/system/*.so{,.1.0} ${pkgdir}/usr/lib
+
+  install -Dm755 "${srcdir}/${pkgname}-${_pkgver}/build/resources/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
+  install -Dm644 "${srcdir}/$pkgname-$_pkgver/build/resources/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  install -Dm644 "${srcdir}/$pkgname-$_pkgver/build/resources/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
+}