Fri May 4 00:01:56 UTC 2012

2 files changed, 90 insertions, 0 deletions

diff --git a/community/doublecmd/PKGBUILD b/community/doublecmd/PKGBUILD
new file mode 100644
index 000000000..1dc0c2a38
--- /dev/null
+++ b/community/doublecmd/PKGBUILD
@@ -0,0 +1,56 @@
+# $Id: PKGBUILD 70226 2012-05-02 13:40:27Z idevolder $
+# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
+# Contributor: (sirocco AT ngs.ru)
+
+pkgbase=doublecmd
+pkgname=('doublecmd-gtk2' 'doublecmd-qt')
+pkgver=0.5.4
+_helpver=0.5.1
+pkgrel=2
+url="http://doublecmd.sourceforge.net/"
+arch=('i686' 'x86_64')
+license=('GPL')
+install="$pkgbase.install"
+provides=("$pkgbase")
+makedepends=('lazarus' 'qt4pas' 'gtk2')
+optdepends=('lua: scripting' 'p7zip: support for 7zip archives' 'libunrar: support for rar archives')
+source=("http://downloads.sourceforge.net/project/$pkgbase/Double%20Commander%20Source/$pkgbase-$pkgver-src.tar.gz"
+	"http://downloads.sourceforge.net/project/$pkgbase/Double%20Commander%20Source/$pkgbase-help-$_helpver-src.tar.gz"
+)
+sha256sums=('480b83279adeba007ad5c54f455733fae3d9c9ee61762e6b5a63e2e67b1cd7b7'
+            'd9f518e05e089b71aaa31c7d4af8177e77594a02be2c316e85e061e63b4c03e5')
+
+build() {
+	cp -a $pkgbase-$pkgver $pkgbase-gtk
+	cp -a $pkgbase-$pkgver $pkgbase-qt
+
+	cd "$srcdir/$pkgbase-gtk"
+	./build.sh beta gtk2
+
+	cd "$srcdir/$pkgbase-qt"
+	./build.sh beta qt
+}
+
+package_doublecmd-gtk2() {
+	pkgdesc="twin-panel (commander-style) file manager (GTK)"
+	depends=('gtk2')
+	cd "$srcdir/$pkgbase-gtk"
+	sed -e 's/LIB_SUFFIX=.*/LIB_SUFFIX=/g' -i ./install/linux/install.sh
+	./install/linux/install.sh --install-prefix="$pkgdir"
+
+	# install doc
+	cd "$srcdir/$pkgbase-help-$_helpver"
+	cp -a * "$pkgdir/usr/share/$pkgbase/doc/"
+}
+
+package_doublecmd-qt() {
+	pkgdesc="twin-panel (commander-style) file manager (QT)"
+	depends=('qt4pas')
+	cd "$srcdir/$pkgbase-qt"
+	sed -e 's/LIB_SUFFIX=.*/LIB_SUFFIX=/g' -i ./install/linux/install.sh
+	./install/linux/install.sh --install-prefix="$pkgdir"
+
+	# install doc
+	cd "$srcdir/$pkgbase-help-$_helpver"
+	cp -a * "$pkgdir/usr/share/$pkgbase/doc/"
+}
diff --git a/community/doublecmd/doublecmd.install b/community/doublecmd/doublecmd.install
new file mode 100644
index 000000000..40d56528f
--- /dev/null
+++ b/community/doublecmd/doublecmd.install
@@ -0,0 +1,34 @@
+update_icons() {
+
+	# Setup Menus
+	if which update-desktop-database
+	then
+		update-desktop-database -q /usr/share/applications
+	fi
+
+	# Setup MIME types
+	if which update-mime-database
+	then
+		update-mime-database /usr/share/mime >/dev/null
+	fi
+
+	# Setup Icons
+	touch -c /usr/share/icons/hicolor
+	if which gtk-update-icon-cache
+	then
+		gtk-update-icon-cache -tq /usr/share/icons/hicolor
+	fi
+
+}
+
+post_install() {
+	update_icons
+}
+
+post_upgrade() {
+	update_icons
+}
+
+post_remove() {
+	update_icons
+}