Tue Apr 5 14:26:38 UTC 2011

2 files changed, 64 insertions, 0 deletions

diff --git a/community/electricsheep/ChangeLog b/community/electricsheep/ChangeLog
new file mode 100644
index 000000000..516a16a97
--- /dev/null
+++ b/community/electricsheep/ChangeLog
@@ -0,0 +1,30 @@
+2010-09-26  Eric Belanger  <eric@archlinux.org>
+
+	* electricsheep 2.7b12-3
+	* Rebuilt against new ffmpeg to improve performance
+
+2009-10-17  Eric Belanger  <eric@archlinux.org>
+
+	* electricsheep 2.7b12-2
+	* Added xscreensaver config
+	* Updated url
+
+2009-07-09  Eric Belanger  <eric@archlinux.org>
+
+	* electricsheep 2.7b12-1
+	* Upstream update
+	* Switched to svn snapshot as source tarballs are no longer provided
+	* Updated url
+	* Splitted flam3 in a separate package
+	* Updated depends
+	* Removed install scriptlet
+
+2008-09-20  Eric Belanger  <eric@archlinux.org>
+
+	* electricsheep 2.6.8-4
+	* Updated for KDE 4 (close FS#11378)
+	* Added xscreensaver optdepends to cleanup post-install messages
+	* FHS man pages
+	* Fixed build issue
+	* Added xscreensaver makedepends and config
+	* Added ChangeLog
diff --git a/community/electricsheep/PKGBUILD b/community/electricsheep/PKGBUILD
new file mode 100644
index 000000000..dd4b57014
--- /dev/null
+++ b/community/electricsheep/PKGBUILD
@@ -0,0 +1,34 @@
+# $Id: PKGBUILD 27614 2010-09-26 06:47:20Z ebelanger $
+# Maintainer: Eric Belanger <eric@archlinux.org>
+
+pkgname=electricsheep
+pkgver=2.7b12
+pkgrel=3
+pkgdesc="A screensaver that realize the collective dream of sleeping computers from all over the internet"
+arch=('i686' 'x86_64')
+url="http://community.electricsheep.org/"
+license=('GPL')
+depends=('curl' 'expat' 'flam3' 'ffmpeg' 'mplayer' 'libglade')
+makedepends=('xscreensaver')
+optdepends=('xscreensaver: to use electricsheep with xscreensaver')
+changelog=ChangeLog
+source=(ftp://ftp.archlinux.org/other/electricsheep/${pkgname}-${pkgver}.tar.bz2)
+md5sums=('9c66691538941593ca9442e087b183d1')
+sha1sums=('fd1c307912905ba456189efbb546ef0fe336fa32')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  install -d "${pkgdir}/usr/share/applications/screensavers"
+  install -d "${pkgdir}/usr/lib/gnome-screensaver/gnome-screensaver"
+  make DESTDIR="${pkgdir}" GNOME_SCREENSAVER_DATADIR="${pkgdir}/usr/share/applications/screensavers" \
+    GNOME_SCREENSAVER_PRIVEXEDIR="${pkgdir}/usr/lib/gnome-screensaver/gnome-screensaver" install
+  install -D -m644 electricsheep.desktop.kde "${pkgdir}/usr/share/kde4/services/ScreenSavers/electricsheep.desktop"
+  install -D -m644 electricsheep.xml "${pkgdir}/usr/share/xscreensaver/config/electricsheep.xml"
+  install -D -m755 electricsheep-saver "${pkgdir}/usr/bin/electricsheep-saver"
+}