Sun Aug 11 01:21:31 PDT 2013

1 files changed, 0 insertions, 76 deletions

diff --git a/community/erlang/PKGBUILD b/community/erlang/PKGBUILD
deleted file mode 100644
index c6f117d3c..000000000
--- a/community/erlang/PKGBUILD
+++ /dev/null
@@ -1,76 +0,0 @@
-# $Id: PKGBUILD 92929 2013-06-19 13:52:02Z arodseth $
-# Maintainer: Lukas Fleischer <archlinux@cryptocrack.de>
-# Maintainer: Alexander Rødseth <rodseth@gmail.com>
-# Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
-# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
-# Contributor: Tom Burdick <thomas.burdick@wrightwoodtech.com>
-# Contributor: Ricardo Catalinas Jiménez <jimenezrick@gmail.com>
-
-pkgbase=erlang
-pkgname=('erlang' 'erlang-unixodbc')
-pkgver=R16B01
-pkgrel=1
-arch=('x86_64' 'i686')
-url='http://www.erlang.org/'
-license=('custom')
-makedepends=('perl' 'mesa' 'lksctp-tools' 'unixodbc' 'wxgtk' 'wxgtk2.9')
-source=("http://www.erlang.org/download/otp_src_${pkgver/_/-}.tar.gz"
-        "http://www.erlang.org/download/otp_doc_man_${pkgver/_/-}.tar.gz")
-sha256sums=('da388bc07b8ebdd008f5bb6c3d2c280e358bd188b5aac3ea01e3a7436315abc0'
-            '71972049fbac73457fb6868be18068edce9f2c9fc2aeeab15f019d4217b6a8c2')
-
-build() {
-  cd "$srcdir/otp_src_${pkgver/_1/}"
-
-  ./configure --prefix=/usr --enable-smp-support --with-odbc
-  make
-}
-
-package_erlang() {
-  pkgdesc='General-purpose concurrent functional programming language developed by Ericsson'
-  depends=('ncurses' 'glu' 'wxgtk' 'wxgtk2.9' 'openssl')
-  optdepends=('erlang-unixodbc: database support'
-              'java-environment: for Java support'
-              'lksctp-tools: for SCTP support')
-  provides=('erlang-nox')
-  conflicts=('erlang-nox')
-
-  cd "$srcdir/otp_src_${pkgver/_1/}"
-
-  make DESTDIR="$pkgdir" install
-
-  # Documentation
-  install -d "$pkgdir/usr/share/doc/erlang"
-  install -m0644 "$srcdir/otp_src_${pkgver/_1/}/README.md" \
-    "$srcdir"/{README,COPYRIGHT} \
-    "$pkgdir/usr/share/doc/erlang"
-
-  # Compressed man pages
-  for page in "$srcdir/man/man?/*"; do gzip $page; done
-  cp -r "$srcdir/man" "$pkgdir/usr/lib/erlang/"
-
-  # License
-  install -Dm0644 "$srcdir/otp_src_${pkgver/_1/}/EPLICENCE" \
-    "$pkgdir/usr/share/licenses/$pkgname/EPLICENCE"
-
-  # Move over files that will be packaged as erlang-unixodbc
-  mkdir "$srcdir/unixodbc"
-  mv "$pkgdir/usr/lib/erlang/lib/odbc"* "$srcdir/unixodbc/"
-  mv "$pkgdir/usr/lib/erlang/man/man3/odbc.3.gz" "$srcdir"
-}
-
-package_erlang-unixodbc() {
-  pkgdesc='Unixodbc support for Erlang'
-  depends=('unixodbc' 'erlang-nox')
-
-  # Get the files that should be packaged as erlang-unixodbc
-  mkdir -p "$pkgdir/usr/lib/erlang/"{lib,man/man3}
-  mv "$srcdir/unixodbc/"* "$pkgdir/usr/lib/erlang/lib/"
-  mv "$srcdir/odbc.3.gz" "$pkgdir/usr/lib/erlang/man/man3/"
-
-  # License
-  install -Dm0644 "$srcdir/otp_src_${pkgver/_1/}/EPLICENCE" \
-    "$pkgdir/usr/share/licenses/$pkgname/EPLICENCE"
-}
-
-# vim:set ts=2 sw=2 et: