Sun Jul 13 03:22:17 UTC 2014

1 files changed, 39 insertions, 0 deletions

diff --git a/community/gnuradio-osmosdr/PKGBUILD b/community/gnuradio-osmosdr/PKGBUILD
new file mode 100644
index 000000000..91d791062
--- /dev/null
+++ b/community/gnuradio-osmosdr/PKGBUILD
@@ -0,0 +1,39 @@
+# $Id: PKGBUILD 115631 2014-07-12 20:27:39Z kkeen $
+# Maintainer: Kyle Keen <keenerd@gmail.com?>
+# Contributor: Dominik Heidler <dheidler@gmail.com>
+pkgname=gnuradio-osmosdr
+_pkgname=gr-osmosdr
+pkgver=0.1.1
+pkgrel=8
+pkgdesc="GNU Radio source block for Funcube Dongle, RTL-SDR, USRP and OsmoSDR devices"
+url="http://sdr.osmocom.org/trac/"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('gnuradio' 'gnuradio-iqbal' 'rtl-sdr' 'gnuradio-fcdproplus' 'hackrf' 'bladerf')
+makedepends=('git' 'cmake' 'boost' 'python2-cheetah' 'swig')
+conflicts=('gr-osmosdr-git')
+replaces=('gr-osmosdr')
+source=("git://git.osmocom.org/gr-osmosdr#tag=v$pkgver")
+md5sums=('SKIP')
+
+# add airspy support?
+
+build() {
+  cd "$srcdir/$_pkgname"
+  sed -i 's/python$/python2/' apps/osmocom_siggen_base.py
+  mkdir build
+  cd build
+  cmake \
+    -Wno-dev \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DPYTHON_EXECUTABLE=$(which python2) \
+    -DPYTHON_INCLUDE_DIR=$(echo /usr/include/python2*) \
+    -DPYTHON_LIBRARY=$(echo /usr/lib/libpython2.*.so) \
+    -DCMAKE_INSTALL_PREFIX=/usr ../
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgname/build/"
+  make DESTDIR="${pkgdir}" install
+}