Tue Apr 5 14:26:38 UTC 2011

1 files changed, 40 insertions, 0 deletions

diff --git a/extra/gtk2/PKGBUILD b/extra/gtk2/PKGBUILD
new file mode 100644
index 000000000..0526600ea
--- /dev/null
+++ b/extra/gtk2/PKGBUILD
@@ -0,0 +1,40 @@
+# $Id: PKGBUILD 99604 2010-11-15 19:29:19Z ibiru $
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgname=gtk2
+pkgver=2.22.1
+pkgrel=1
+pkgdesc="The GTK+ Toolkit (v2)"
+arch=('i686' 'x86_64')
+url="http://www.gtk.org/"
+install=gtk2.install
+depends=('atk>=1.30.0' 'pango>=1.28.0' 'libxcursor' 'libxinerama' 'libxrandr>=1.3.0' 'libxi>=1.3' 'libxcomposite' 'libxdamage' 'heimdal>=1.3.2' 'gnutls>=2.8.6' 'shared-mime-info' 'cairo>=1.10.0' 'libcups>=1.4.4' 'gdk-pixbuf2>=2.22.1')
+makedepends=('gtk-doc' 'gobject-introspection')
+replaces=('gtkprint-cups' 'gail')
+conflicts=('gtkprint-cups' 'gail')
+provides=('gail=1.22.3')
+options=('!libtool' '!docs')
+backup=(etc/gtk-2.0/gtkrc)
+license=('LGPL')
+source=(http://ftp.gnome.org/pub/gnome/sources/gtk+/2.22/gtk+-${pkgver}.tar.bz2
+        xid-collision-debug.patch old-icon-symlinks.patch)
+sha256sums=('965bc124f0d25087c4cb2a64cbfd7e4f896e05be8d560fbba68dd8685ba24d07'
+            'd758bb93e59df15a4ea7732cf984d1c3c19dff67c94b957575efea132b8fe558'
+            '1298e4103f71d0304378f1e7503011150f6f68398ae8ebae5522a48feaea7c0d')
+
+build() {
+  cd "${srcdir}/gtk+-${pkgver}"
+  patch -Np1 -i "${srcdir}/xid-collision-debug.patch"
+  patch -Np1 -i "${srcdir}/old-icon-symlinks.patch"
+
+  CXX=/bin/false ./configure --prefix=/usr \
+      --sysconfdir=/etc \
+      --localstatedir=/var \
+      --with-xinput=yes
+  make
+  make DESTDIR="${pkgdir}" install
+
+  sed -i "s#env python#env python2#" $pkgdir/usr/bin/gtk-builder-convert
+
+  echo 'gtk-fallback-icon-theme = "gnome"' > "${pkgdir}/etc/gtk-2.0/gtkrc"
+}