Thu May 31 00:03:48 UTC 2012

4 files changed, 154 insertions, 0 deletions

diff --git a/kde-unstable/kdebase/PKGBUILD b/kde-unstable/kdebase/PKGBUILD
new file mode 100644
index 000000000..5a2078269
--- /dev/null
+++ b/kde-unstable/kdebase/PKGBUILD
@@ -0,0 +1,120 @@
+# $Id: PKGBUILD 160096 2012-05-29 22:29:11Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdebase
+pkgname=('kdebase-dolphin'
+         'kdebase-kdepasswd'
+         'kdebase-kdialog'
+         'kdebase-keditbookmarks'
+         'kdebase-kfind'
+         'kdebase-konq-plugins'
+         'kdebase-konqueror'
+         'kdebase-lib'
+         'kdebase-plasma')
+pkgver=4.8.80
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdebase')
+makedepends=('kdelibs' 'cmake' 'automoc4' 'tidyhtml')
+source=("http://download.kde.org/unstable/${pkgver}/src/kde-baseapps-${pkgver}.tar.xz")
+sha1sums=('7057f83087295391c2bbbd1d75a79cf1ec696a20')
+
+build() {
+	cd ${srcdir}
+	mkdir build
+	cd build
+	cmake ../kde-baseapps-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdebase-dolphin() {
+	pkgdesc='File Manager'
+	depends=('kdebase-runtime' 'kdebase-lib')
+	optdepends=('kdegraphics-svgpart: thumbailers for SVG files'
+                'kdegraphics-thumbnailers: thumbnailers for graphics file'
+                'ruby: servicemenu installation')
+	url="http://kde.org/applications/system/dolphin/"
+        install=kdebase-dolphin.install
+	cd $srcdir/build/dolphin
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/dolphin
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-kdepasswd() {
+	pkgdesc='Change Password'
+	depends=('kdebase-runtime' 'kdebase-lib')
+	cd $srcdir/build/kdepasswd
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kdepasswd
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-kdialog() {
+	pkgdesc='A utility for displaying dialog boxes from shell scripts'
+	depends=('kdebase-runtime')
+	cd $srcdir/build/kdialog
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-keditbookmarks() {
+	pkgdesc='Bookmark Organizer and Editor'
+	depends=('kdebase-runtime')
+	cd $srcdir/build/keditbookmarks
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-kfind() {
+	pkgdesc='Find Files/Folders'
+	depends=('kdebase-runtime' 'kdebase-lib')
+	url="http://kde.org/applications/utilities/kfind/"
+	install='kdebase.install'
+	cd $srcdir/build/kfind
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kfind
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-konq-plugins() {
+	pkgdesc='Extra plugins for Konqueror'
+	depends=('kdebase-konqueror' 'tidyhtml')
+	replaces=('konq-plugins')
+	install='kdebase.install'
+	cd $srcdir/build/konq-plugins
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-konqueror() {
+	pkgdesc='KDE File Manager & Web Browser'
+	depends=('kdebase-dolphin' 'kdebase-keditbookmarks')
+	optdepends=('kwebkitpart: to enable webkit engine')
+	url="http://kde.org/applications/internet/konqueror/"
+	install='kdebase-konqueror.install'
+        conflicts=('kdebase-nsplugins')
+        replaces=('kdebase-nsplugins')
+        for i in konqueror doc/konqueror nsplugins; do
+              cd $srcdir/build/${i}
+              make DESTDIR=$pkgdir install
+        done
+}
+
+package_kdebase-lib() {
+	pkgdesc='KDE libraries for the basic desktop applications'
+	groups=()
+	depends=('kdelibs')
+	cd $srcdir/build/lib
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-plasma() {
+	pkgdesc='Display the contents of folders (User´s home folder as default)'
+	depends=('kdebase-workspace' 'kdebase-lib')
+	cd $srcdir/build/plasma
+	make DESTDIR=$pkgdir install
+}
diff --git a/kde-unstable/kdebase/kdebase-dolphin.install b/kde-unstable/kdebase/kdebase-dolphin.install
new file mode 100644
index 000000000..660593cf5
--- /dev/null
+++ b/kde-unstable/kdebase/kdebase-dolphin.install
@@ -0,0 +1,11 @@
+post_install() {
+    update-desktop-database -q
+}
+
+post_upgrade() {
+    post_install
+}
+
+post_remove() {
+    post_install
+}
diff --git a/kde-unstable/kdebase/kdebase-konqueror.install b/kde-unstable/kdebase/kdebase-konqueror.install
new file mode 100644
index 000000000..5495fb1b5
--- /dev/null
+++ b/kde-unstable/kdebase/kdebase-konqueror.install
@@ -0,0 +1,12 @@
+post_install() {
+    xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+    update-desktop-database -q
+}
+
+post_upgrade() {
+    post_install
+}
+
+post_remove() {
+    post_install
+}
diff --git a/kde-unstable/kdebase/kdebase.install b/kde-unstable/kdebase/kdebase.install
new file mode 100644
index 000000000..e70c054ec
--- /dev/null
+++ b/kde-unstable/kdebase/kdebase.install
@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}