Fri Sep 30 23:14:37 UTC 2011

2 files changed, 88 insertions, 0 deletions

diff --git a/multilib-testing/lib32-json-c/PKGBUILD b/multilib-testing/lib32-json-c/PKGBUILD
new file mode 100644
index 000000000..07670938e
--- /dev/null
+++ b/multilib-testing/lib32-json-c/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>
+# Contributor: congyiwu <congyiwu AT gmail DOT com>
+
+_pkgbasename=json-c
+pkgname=lib32-$_pkgbasename
+pkgver=0.9
+pkgrel=1
+pkgdesc="A JSON implementation in C (32-bit)"
+url="http://oss.metaparadigm.com/json-c/"
+license=("MIT")
+arch=('x86_64')
+depends=('lib32-glibc' $_pkgbasename)
+makedepends=('gcc-multilib' 'libtool-multilib')
+source=(http://oss.metaparadigm.com/$_pkgbasename/$_pkgbasename-$pkgver.tar.gz)
+md5sums=('3a13d264528dcbaf3931b0cede24abae')
+options=(!libtool)
+build() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+
+  export CC="gcc -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure --prefix=/usr --libdir=/usr/lib32
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  rm -r "$pkgdir/usr/include"
+
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}
diff --git a/multilib-testing/lib32-libpulse/PKGBUILD b/multilib-testing/lib32-libpulse/PKGBUILD
new file mode 100644
index 000000000..4e298ac9b
--- /dev/null
+++ b/multilib-testing/lib32-libpulse/PKGBUILD
@@ -0,0 +1,52 @@
+# $Id: PKGBUILD 56027 2011-09-29 09:08:13Z heftig $
+# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Contributor: Corrado Primier <bardo@aur.archlinux.org>
+# Contributor: William Rea <sillywilly@gmail.com>
+
+_pkgbasename=libpulse
+pkgname=lib32-$_pkgbasename
+pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
+pkgver=1.0
+pkgrel=1
+arch=(x86_64)
+url="http://pulseaudio.org/"
+license=(GPL LGPL)
+depends=(lib32-dbus-core lib32-xcb-util lib32-json-c 
+         lib32-libasyncns lib32-libcap lib32-libxtst lib32-libsm lib32-libsamplerate
+         $_pkgbasename)
+makedepends=(gcc-multilib libtool-multilib intltool lib32-glib2 lib32-speex)
+optdepends=('lib32-alsa-plugins: ALSA support')
+provides=("lib32-pulseaudio=$pkgver")
+conflicts=(lib32-pulseaudio)
+replaces=(lib32-pulseaudio)
+options=(!emptydirs !libtool !makeflags)
+source=("http://freedesktop.org/software/pulseaudio/releases/pulseaudio-$pkgver.tar.xz")
+sha256sums=('e63464f8a0975446e2b4cfe768b615a66735c8d092b2366d2bdc7a2a04a249be')
+
+_libs="libpulsecommon-$pkgver.la libpulse.la libpulse-simple.la libpulse-mainloop-glib.la libpulsedsp.la"
+
+build() {
+  cd "$srcdir/pulseaudio-$pkgver"
+
+  export CC="gcc -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure --prefix=/usr \
+    --sysconfdir=/etc \
+    --libdir=/usr/lib32 \
+    --libexecdir=/usr/lib32 \
+    --localstatedir=/var \
+    --disable-hal \
+    --disable-tcpwrap \
+    --disable-rpath \
+    --disable-default-build-tests
+
+  make -C src $_libs
+}
+
+package() {
+  cd "$srcdir/pulseaudio-$pkgver"
+  make -C src lib_LTLIBRARIES="$_libs" DESTDIR="$pkgdir" install-libLTLIBRARIES
+  make DESTDIR="$pkgdir" install-pkgconfigDATA
+}