Wed Sep 7 15:14:25 UTC 2011

1 files changed, 104 insertions, 0 deletions

diff --git a/staging/kdeartwork/PKGBUILD b/staging/kdeartwork/PKGBUILD
new file mode 100644
index 000000000..f6aefef26
--- /dev/null
+++ b/staging/kdeartwork/PKGBUILD
@@ -0,0 +1,104 @@
+# $Id: PKGBUILD 137253 2011-09-06 21:35:12Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdeartwork
+pkgname=('kdeartwork-aurorae'
+         'kdeartwork-colorschemes'
+         'kdeartwork-desktopthemes'
+         'kdeartwork-emoticons'
+         'kdeartwork-iconthemes'
+         'kdeartwork-kscreensaver'
+         'kdeartwork-sounds'
+         'kdeartwork-styles'
+         'kdeartwork-wallpapers'
+         'kdeartwork-weatherwallpapers')
+pkgver=4.7.1
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdeartwork')
+makedepends=('pkgconfig' 'cmake' 'automoc4' 'xscreensaver' 'eigen'
+	         'kdebase-workspace' 'libkexiv2')
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2")
+sha1sums=('df8c3225b025e0afb43efb73a5c53573ee3be77e')
+
+build() {
+	cd $srcdir
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdeartwork-aurorae() {
+	pkgdesc='An Aurorae theme based on the Oxygen plasma theme'
+	cd $srcdir/build/aurorae
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-colorschemes() {
+	pkgdesc='KDE color schemes'
+    replaces=('kdeaccessibility-colorschemes')
+	cd $srcdir/build/ColorSchemes
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-desktopthemes() {
+	pkgdesc='KDE desktop themes'
+	cd $srcdir/build/desktopthemes
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-emoticons() {
+	pkgdesc='KDE emoticons'
+	cd $srcdir/build/emoticons
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-iconthemes() {
+	pkgdesc='KDE icon themes'
+    replaces=('kdeaccessibility-iconthemes')
+	cd $srcdir/build/IconThemes
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-kscreensaver() {
+	pkgdesc='KDE screensaver'
+	depends=('kdebase-workspace' 'libkexiv2')
+	cd $srcdir/build/kscreensaver
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-sounds() {
+	pkgdesc='KDE sounds'
+	cd $srcdir/build/sounds
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-styles() {
+	pkgdesc='KDE styles'
+	depends=('kdebase-workspace')
+	cd $srcdir/build/styles
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/kwin-styles
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-wallpapers() {
+	pkgdesc='KDE wallpapers'
+	cd $srcdir/build/wallpapers
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/HighResolutionWallpapers
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeartwork-weatherwallpapers() {
+	pkgdesc='KDE weather wallpapers'
+	cd $srcdir/build/WeatherWallpapers
+	make DESTDIR=$pkgdir install
+}