Wed Jul 6 23:10:44 UTC 2011

2 files changed, 140 insertions, 0 deletions

diff --git a/staging/kdebase/PKGBUILD b/staging/kdebase/PKGBUILD
new file mode 100644
index 000000000..354b64302
--- /dev/null
+++ b/staging/kdebase/PKGBUILD
@@ -0,0 +1,129 @@
+# $Id: PKGBUILD 130256 2011-07-04 19:27:25Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdebase
+pkgname=('kdebase-dolphin'
+         'kdebase-kdepasswd'
+         'kdebase-kdialog'
+         'kdebase-keditbookmarks'
+         'kdebase-kfind'
+         'kdebase-konqueror'
+         'kdebase-konsole'
+         'kdebase-kwrite'
+         'kdebase-lib'
+         'kdebase-plasma')
+pkgver=4.6.5
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdebase')
+makedepends=('kdebase-workspace' 'pkgconfig' 'cmake' 'automoc4')
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2")
+sha1sums=('1a902d22956daaf380ceefe68f8db75b8b760ae6')
+
+build() {
+	cd ${srcdir}
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdebase-dolphin() {
+	pkgdesc='File Manager'
+	depends=('kdebase-runtime' 'kdebase-lib')
+	optdepends=('ruby: servicemenu installation')
+	url="http://kde.org/applications/system/dolphin/"
+	cd $srcdir/build/dolphin
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/dolphin
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-kdepasswd() {
+	pkgdesc='Change Password'
+	depends=('kdebase-runtime' 'kdebase-lib')
+	cd $srcdir/build/kdepasswd
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kdepasswd
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-kdialog() {
+	pkgdesc='A utility for displaying dialog boxes from shell scripts'
+	depends=('kdebase-runtime')
+	cd $srcdir/build/kdialog
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-keditbookmarks() {
+	pkgdesc='Bookmark Organizer and Editor'
+	depends=('kdebase-runtime')
+	cd $srcdir/build/keditbookmarks
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-kfind() {
+	pkgdesc='Find Files/Folders'
+	depends=('kdebase-runtime' 'kdebase-lib')
+	url="http://kde.org/applications/utilities/kfind/"
+	install='kdebase.install'
+	cd $srcdir/build/kfind
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kfind
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-konqueror() {
+	pkgdesc='KDE File Manager & Web Browser'
+	depends=('kdebase-dolphin' 'kdebase-keditbookmarks')
+	optdepends=('kwebkitpart: to enable webkit engine')
+	url="http://kde.org/applications/internet/konqueror/"
+	install='kdebase.install'
+    conflicts=('kdebase-nsplugins')
+    replaces=('kdebase-nsplugins')
+    for i in konqueror doc/konqueror nsplugins; do
+        cd $srcdir/build/${i}
+        make DESTDIR=$pkgdir install
+    done
+}
+
+package_kdebase-konsole() {
+	pkgdesc='Terminal'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/system/konsole/"
+	cd $srcdir/build/konsole
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/konsole/doc/manual
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-kwrite() {
+	pkgdesc='Text Editor'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kwrite/"
+	cd $srcdir/build/kwrite
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kwrite
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-lib() {
+	pkgdesc='KDE libraries for the basic desktop applications'
+	groups=()
+	depends=('kdelibs')
+	cd $srcdir/build/lib
+	make DESTDIR=$pkgdir install
+}
+
+package_kdebase-plasma() {
+	pkgdesc='Display the contents of folders (User´s home folder as default)'
+	depends=('kdebase-workspace' 'kdebase-lib')
+	cd $srcdir/build/plasma
+	make DESTDIR=$pkgdir install
+}
diff --git a/staging/kdebase/kdebase.install b/staging/kdebase/kdebase.install
new file mode 100644
index 000000000..e70c054ec
--- /dev/null
+++ b/staging/kdebase/kdebase.install
@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}