Sun May 15 22:39:30 UTC 2011

1 files changed, 53 insertions, 0 deletions

diff --git a/testing/curl/PKGBUILD b/testing/curl/PKGBUILD
new file mode 100644
index 000000000..13048e9d9
--- /dev/null
+++ b/testing/curl/PKGBUILD
@@ -0,0 +1,53 @@
+# $Id: PKGBUILD 123955 2011-05-14 18:55:23Z angvp $
+# Maintainer: Angel Velasquez <angvp@archlinux.org>
+# Contributor: Eric Belanger <eric@archlinux.org>
+# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+
+pkgname=curl
+pkgver=7.21.6
+pkgrel=2
+pkgdesc="An URL retrival utility and library"
+arch=('i686' 'x86_64')
+url="http://curl.haxx.se"
+license=('MIT')
+depends=('zlib' 'openssl' 'bash' 'ca-certificates' 'libssh2')
+options=('!libtool')
+source=(http://curl.haxx.se/download/${pkgname}-${pkgver}.tar.bz2
+        curlbuild.h)
+
+[[ $CARCH == "x86_64" ]] && _curlbuild=curlbuild-64.h
+[[ $CARCH == "i686" ]] && _curlbuild=curlbuild-32.h
+md5sums=('6611989a81ebd7b03a35adc3001ddee0'
+         '751bd433ede935c8fae727377625a8ae')
+
+build() {
+    cd ${srcdir}/${pkgname}-${pkgver}
+
+    ./configure \
+        --with-random=/dev/urandom \
+        --prefix=/usr \
+        --mandir=/usr/share/man \
+        --disable-dependency-tracking \
+        --enable-ipv6 \
+        --disable-ldaps \
+        --disable-ldap \
+        --enable-manual \
+        --enable-versioned-symbols \
+        --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
+        --without-libidn \
+        --enable-threaded-resolver
+    make
+}
+
+package() {
+    cd ${srcdir}/${pkgname}-${pkgver}
+
+    make DESTDIR=${pkgdir} install
+    install -Dm644 COPYING \
+        ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
+    install -Dm644 docs/libcurl/libcurl.m4 \
+        ${pkgdir}/usr/share/aclocal/libcurl.m4
+    mv "${pkgdir}/usr/include/curl/curlbuild.h" "${pkgdir}/usr/include/curl/${_curlbuild}"
+    install -m 644 ${srcdir}/curlbuild.h "${pkgdir}/usr/include/curl/curlbuild.h"
+}