Thu Jan 26 23:14:55 UTC 2012

1 files changed, 80 insertions, 0 deletions

diff --git a/testing/kdebase-workspace/PKGBUILD b/testing/kdebase-workspace/PKGBUILD
new file mode 100644
index 000000000..b4f171fad
--- /dev/null
+++ b/testing/kdebase-workspace/PKGBUILD
@@ -0,0 +1,80 @@
+# $Id: PKGBUILD 147576 2012-01-25 23:16:04Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgname=kdebase-workspace
+_pkgname=kde-workspace
+pkgver=4.8.0
+pkgrel=1
+pkgdesc="KDE Base Workspace"
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde')
+# note on libxdamage:
+# 	not detected by namcap because libgl depends on it
+#	but nvidia providing libgl does not depend on libxdamage
+depends=('kdepim-runtime' 'lm_sensors' 'libraw1394' 'libqalculate'
+         'qimageblitz' 'polkit-kde' 'consolekit' 'xorg-xprop' 'libxdamage'
+         'libxklavier' 'xorg-xsetroot' 'libxcomposite' 'libxinerama'
+         'xorg-xrdb' 'libgles' 'libegl' 'kactivities' 'libxres' 'libxtst')
+makedepends=('cmake' 'automoc4' 'boost' 'kdebindings-python' 'networkmanager')
+optdepends=('kde-wallpapers: wallpapers for KDE Plasma Workspaces')
+replaces=('kdmtheme' 'kde-common' 'guidance-power-manager' 'policykit-kde'
+          'kdebase-kinfocenter')
+conflicts=('kde-common' 'guidance-power-manager' 'policykit-kde'
+           'kdebase-kinfocenter')
+install="${pkgname}.install"
+backup=('usr/share/config/kdm/kdmrc'
+        'etc/pam.d/kde'
+        'etc/pam.d/kde-np'
+        'etc/pam.d/kscreensaver')
+options=('emptydirs')
+source=("http://download.kde.org/stable/${pkgver}/src/${_pkgname}-${pkgver}.tar.bz2"
+        'kdm' 'kde.pam' 'kde-np.pam' 'kscreensaver.pam'
+        'fixpath.patch' 'terminate-server.patch' 'kdm-xinitrd.patch')
+sha1sums=('4c471b159315b084c65196b0c93c34981a9105c5'
+          '5db3a245201bd4a50e65aa2ef583cf5490e4f646'
+          'e4198a443703f749b58a4fec88362fced1b45789'
+          '264e395c2c44cdda5a242c6dee649afab44cd6e5'
+          '106635aa1aae51d6f0668b1853f6c49a4fe9d3d8'
+          'd7b5883f7e65c6839b1f65f94d58026673dd0226'
+          'ac7bc292c865bc1ab8c02e6341aa7aeaf1a3eeee'
+          'd509dac592bd8b310df27991b208c95b6d907514')
+
+build() {
+	cd "${srcdir}"/${_pkgname}-${pkgver}
+	patch -p1 -i "${srcdir}"/kdm-xinitrd.patch
+	patch -p0 -i "${srcdir}"/fixpath.patch
+	patch -p0 -i "${srcdir}"/terminate-server.patch
+
+	cd "${srcdir}"
+	mkdir build
+	cd build
+	cmake ../${_pkgname}-${pkgver} \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_SKIP_RPATH=ON \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DWITH_Xmms=OFF \
+        -DWITH_Googlegadgets=OFF \
+        -DWITH_libgps=OFF \
+        -DWITH_OpenGLES=ON \
+        -DKWIN_BUILD_WITH_OPENGLES=ON \
+        -DPYTHON_EXECUTABLE=/usr/bin/python2
+	make
+}
+
+package() {
+	cd "${srcdir}"/build
+	make DESTDIR="${pkgdir}" install
+
+	install -D -m755 "${srcdir}"/kdm "${pkgdir}"/etc/rc.d/kdm
+	install -D -m644 "${srcdir}"/kde.pam "${pkgdir}"/etc/pam.d/kde
+	install -D -m644 "${srcdir}"/kde-np.pam "${pkgdir}"/etc/pam.d/kde-np
+	install -D -m644 "${srcdir}"/kscreensaver.pam "${pkgdir}"/etc/pam.d/kscreensaver
+	install -d -m755 "${pkgdir}"/usr/share/xsessions/
+	ln -sf /usr/share/apps/kdm/sessions/kde-plasma{,-safe}.desktop "${pkgdir}"/usr/share/xsessions/
+	install -d -m755 "${pkgdir}"/etc/kde/{env,shutdown}
+
+	install -d -g 135 -o 135 "${pkgdir}"/var/lib/kdm
+}