Mon Jul 11 18:34:51 UTC 2011

3 files changed, 0 insertions, 138 deletions

diff --git a/testing/opencv/PKGBUILD b/testing/opencv/PKGBUILD
deleted file mode 100644
index 893bb15dc..000000000
--- a/testing/opencv/PKGBUILD
+++ /dev/null
@@ -1,110 +0,0 @@
-# $Id: PKGBUILD 130774 2011-07-07 23:14:56Z foutrelis $
-# Maintainer: Ray Rashif <schiv@archlinux.org>
-# Contributor: Tobias Powalowski <tpowa@archlinux.org>
-
-pkgbase=opencv
-pkgname=('opencv' 'opencv-docs' 'opencv-samples')
-_realname=OpenCV
-pkgver=2.3.0
-pkgrel=1
-pkgdesc="Open Source Computer Vision Library"
-arch=('i686' 'x86_64')
-license=('BSD')
-url="http://opencv.willowgarage.com/"
-depends=('jasper' 'gstreamer0.10-base' 'openexr'
-         'gtk2' 'xine-lib' 'libdc1394' 'v4l-utils')
-makedepends=('pkg-config' 'cmake' 'python2-numpy' 'eigen2')
-optdepends=('python2-numpy: Python 2.x interface'
-            'eigen2')
-options=('!libtool')
-source=("http://downloads.sourceforge.net/opencvlibrary/$_realname-$pkgver.tar.bz2"
-        'pypkgpath_nondebian.patch')
-md5sums=('dea5e9df241ac37f4439da16559e420d'
-         'eb884bad665047276e80556e44043a43')
-
-_cmakeopts=('-D CMAKE_BUILD_TYPE=Release'
-            '-D CMAKE_INSTALL_PREFIX=/usr'
-            '-D CMAKE_SKIP_RPATH=ON'
-            '-D BUILD_TESTS=OFF'
-            '-D ENABLE_SSE=ON'
-            '-D ENABLE_SSE2=ON'
-            '-D ENABLE_SSE3=OFF'
-            '-D ENABLE_SSSE3=OFF'
-            '-D ENABLE_SSE41=OFF'
-            '-D ENABLE_SSE42=OFF'
-            '-D BUILD_EXAMPLES=ON'
-            '-D INSTALL_C_EXAMPLES=ON'
-            '-D INSTALL_PYTHON_EXAMPLES=ON'
-            '-D WITH_XINE=ON'
-            '-D WITH_QT=OFF'
-            '-D WITH_QT_OPENGL=OFF'
-            '-D WITH_UNICAP=OFF'
-            '-D WITH_PVAPI=OFF'
-            '-D WITH_OPENNI=OFF'
-            '-D WITH_TBB=OFF'
-            '-D WITH_IPP=OFF'
-            '-D WITH_CUDA=OFF'
-            '-D USE_FAST_MATH=ON')
-
-build() {
-  cd "$srcdir/$_realname-$pkgver"
-
-  # fix upstream's assumption of "debian-based"
-  patch -Np1 -i "$srcdir/pypkgpath_nondebian.patch"
-
-  # x64, i.e "Athlon64" and upwards, can use SSE3
-  [ $CARCH = x86_64 ] && \
-    _cmakeopts=${_cmakeopts[@]/ENABLE_SSE3=OFF/ENABLE_SSE3=ON}
-
-  cmake ${_cmakeopts[@]} .
-
-  make
-}
-
-package_opencv() {
-  install=$pkgname.install
-
-  cd "$srcdir/$_realname-$pkgver"
-
-  make DESTDIR="$pkgdir" install
-
-  # install license file
-  install -Dm644 "$srcdir/$_realname-$pkgver/doc/license.txt" \
-    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-
-  # separate docs package; also be -R friendly
-  [ -d "$pkgdir/usr/share/opencv/doc" ] && \
-    mv "$pkgdir/usr/share/opencv/doc" "$srcdir/opencv-doc"
-
-  # separate samples package
-  [ -d "$pkgdir/usr/share/opencv/samples" ] && \
-    mv "$pkgdir/usr/share/opencv/samples" "$srcdir/opencv-samples"
-}
-
-package_opencv-docs() {
-  pkgdesc+=" (documentation)"
-  #arch=('any')
-  depends=()
-  optdepends=()
-  options=('docs')
-
-  cd "$srcdir"
-
-  mkdir -p "$pkgdir/usr/share/doc"
-  cp -r opencv-doc "$pkgdir/usr/share/doc/opencv"
-}
-
-package_opencv-samples() {
-  pkgdesc+=" (samples)"
-  #arch=('any')
-  depends=()
-  optdepends=()
-  options=()
-
-  cd "$srcdir"
-
-  mkdir -p "$pkgdir/usr/share/opencv"
-  cp -r opencv-samples "$pkgdir/usr/share/opencv/samples"
-}
-
-# vim:set ts=2 sw=2 et:
diff --git a/testing/opencv/opencv.install b/testing/opencv/opencv.install
deleted file mode 100644
index 7709a9cc3..000000000
--- a/testing/opencv/opencv.install
+++ /dev/null
@@ -1,12 +0,0 @@
-post_install() {
-	echo "==> Documentation and samples are in separate packages:"
-	echo
-	echo "* opencv-docs"
-	echo "* opencv-samples"
-}
-
-post_upgrade() {
-	post_install
-}
-
-# vim:set ts=2 sw=2 et:
diff --git a/testing/opencv/pypkgpath_nondebian.patch b/testing/opencv/pypkgpath_nondebian.patch
deleted file mode 100644
index 7c2d44b09..000000000
--- a/testing/opencv/pypkgpath_nondebian.patch
+++ /dev/null
@@ -1,16 +0,0 @@
-diff -aur OpenCV-2.3.0.orig/CMakeLists.txt OpenCV-2.3.0/CMakeLists.txt
---- OpenCV-2.3.0.orig/CMakeLists.txt 2011-07-07 17:31:35.656946629 +0800
-+++ OpenCV-2.3.0/CMakeLists.txt	2011-07-07 17:40:34.110696242 +0800
-@@ -620,11 +620,7 @@
- string(REGEX MATCH "[0-9].[0-9]" PYTHON_VERSION_MAJOR_MINOR "${PYTHON_VERSION_FULL}")
- if(UNIX)
-     set(PYTHON_PLUGIN_INSTALL_PATH lib/python${PYTHON_VERSION_MAJOR_MINOR}/site-packages/opencv)
--    if(APPLE)
--        set(PYTHON_PACKAGES_PATH lib/python${PYTHON_VERSION_MAJOR_MINOR}/site-packages CACHE PATH "Where to install the python packages.")
--    else() #debian based assumed, install to the dist-packages.
--       set(PYTHON_PACKAGES_PATH lib/python${PYTHON_VERSION_MAJOR_MINOR}/dist-packages CACHE PATH "Where to install the python packages.")
--    endif()
-+    set(PYTHON_PACKAGES_PATH lib/python${PYTHON_VERSION_MAJOR_MINOR}/site-packages CACHE PATH "Where to install the python packages.")
- endif()
- if(WIN32)
-     get_filename_component(PYTHON_PATH "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Python\\PythonCore\\${PYTHON_VERSION_MAJOR_MINOR}\\InstallPath]" ABSOLUTE CACHE)