Mon Sep 26 23:14:33 UTC 2011

1 files changed, 48 insertions, 0 deletions

diff --git a/~fauno/haskell-hs-bibutils/PKGBUILD b/~fauno/haskell-hs-bibutils/PKGBUILD
new file mode 100644
index 000000000..46816e9c2
--- /dev/null
+++ b/~fauno/haskell-hs-bibutils/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Ivy Foster <joyfulgirl (at) archlinux (dot) # us>
+# Contributor: Alexander Dunlap <alexander.dunlap at gmail # dot com>
+
+_hkgname=hs-bibutils
+pkgname=haskell-hs-bibutils
+pkgver=4.12
+pkgrel=4
+pkgdesc="Haskell bindings to bibutils, the bibliography conversion utilities."
+url="http://hackage.haskell.org/package/${_hkgname}"
+license=('GPL')
+arch=('i686' 'x86_64')
+makedepends=()
+depends=('ghc' 'haskell-syb=0.3' 'bibutils-dynamic')
+options=('strip')
+source=(http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+install=${pkgname}.install
+md5sums=('4c4647b34246a4d35f1d1cfb10e6720a')
+
+build() {
+    cd ${srcdir}/${_hkgname}-${pkgver}
+    runhaskell Setup configure -O \
+        --enable-split-objs \
+        --enable-shared \
+        --prefix=/usr \
+        --docdir=/usr/share/doc/${pkgname} \
+        --libsubdir=\$compiler/site-local/\$pkgid \
+        --enable-library-profiling
+    runhaskell Setup build
+    runhaskell Setup haddock
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r \
+        -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" \
+        unregister.sh
+}
+
+package() {
+    cd ${srcdir}/${_hkgname}-${pkgver}
+    install -D -m744 register.sh \
+        ${pkgdir}/usr/share/haskell/${pkgname}/register.sh
+    install -m744 unregister.sh \
+        ${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh
+    install -d -m755 \
+        ${pkgdir}/usr/share/doc/ghc/html/libraries
+    ln -s /usr/share/doc/${pkgname}/html \
+        ${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}
+    runhaskell Setup copy --destdir=${pkgdir}
+}