1 files changed, 51 insertions, 0 deletions
diff --git a/community-staging/deadbeef/PKGBUILD b/community-staging/deadbeef/PKGBUILD
new file mode 100644
index 000000000..4b49c0602
--- /dev/null
+++ b/community-staging/deadbeef/PKGBUILD
@@ -0,0 +1,51 @@
+# $Id: PKGBUILD 57696 2011-11-01 10:47:22Z jelle $
+# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
+# Contributor: Alexey Yakovenko <waker@users.sourceforge.net>
+
+pkgname=deadbeef
+pkgver=0.5.1
+pkgrel=3
+pkgdesc='An audio player for GNU/Linux based on GTK2.'
+arch=('i686' 'x86_64')
+url='http://deadbeef.sourceforge.net'
+license=('GPL2')
+depends=('gtk2' 'alsa-lib' 'hicolor-icon-theme' 'desktop-file-utils')
+makedepends=('libvorbis' 'libmad' 'flac' 'curl' 'imlib2' 'wavpack' 'libsndfile' 'libcdio' 'libcddb'
+             'ffmpeg' 'libx11' 'faad2' 'zlib' 'intltool' 'pkgconfig' 'libpulse' 'libzip'
+             'libsamplerate')
+optdepends=('libsamplerate: for Resampler plugin'
+            'libvorbis: for Ogg Vorbis playback'
+            'libmad: for MP1/MP2/MP3 playback'
+            'flac: for FLAC playback'
+            'curl: for Last.fm scrobbler, SHOUTcast, Icecast, Podcast support'
+            'imlib2: for artwork plugin'
+            'wavpack: for WavPack playback'
+            'libsndfile: for Wave playback'
+            'libcdio: audio cd plugin'
+            'libcddb: audio cd plugin'
+            'ffmpeg: for WMA, AA, OMA, AC, etc.'
+            'faad2: for AAC/MP4 support'
+            'dbus: for OSD notifications support'
+            'pulseaudio: for PulseAudio output plugin'
+            'libx11: for global hotkeys plugin'
+            'zlib: for Audio Overload plugin'
+            'libzip: for vfs_zip plugin')
+options=('!libtool')
+install='deadbeef.install'
+source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}-${pkgver}.tar.bz2" "ffmpeg.patch")
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  patch -Np1 -i $srcdir/ffmpeg.patch
+
+  ./configure --prefix=/usr
+  make
+}
+
+package () {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  make prefix="${pkgdir}/usr" install
+}
+md5sums=('be8359d1bd9cf7679cf2ca748996e726'
+         '6cc7623734af310095534c361c9f64e8')