1 files changed, 42 insertions, 0 deletions
diff --git a/community-staging/kdenlive/PKGBUILD b/community-staging/kdenlive/PKGBUILD
new file mode 100644
index 000000000..1a905df42
--- /dev/null
+++ b/community-staging/kdenlive/PKGBUILD
@@ -0,0 +1,42 @@
+# $Id: PKGBUILD 72367 2012-06-13 07:48:34Z spupykin $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Zuf <kontakt.zuf@gmail.com>
+# Contributor: Darwin Bautista <djclue917@gmail.com>
+
+pkgname=kdenlive
+pkgver=0.9.2
+pkgrel=2
+pkgdesc="A non-linear video editor for Linux"
+arch=('i686' 'x86_64')
+# http://download.kde.org/stable/kdenlive/
+url="http://www.kdenlive.org/"
+license=('GPL')
+depends=('kdebase-runtime' 'mlt' 'dvgrab' 'qjson' 'qimageblitz'
+	 'libqzeitgeist')
+makedepends=('automoc4' 'cmake' 'gettext' 'mesa')
+optdepends=('recordmydesktop'
+	    'dvdauthor'
+	    'mkisolinux'
+	    'xine-ui')
+install=kdenlive.install
+options=('docs')
+source=(http://download.kde.org/stable/kdenlive/$pkgver/src/kdenlive-$pkgver.tar.bz2)
+md5sums=('40f108f26e2c2e08807a1c183d8764ec')
+
+build() {
+  export LDFLAGS="$LDFLAGS -lX11"
+  cd "${srcdir}"
+  mkdir -p build
+  cd build
+  cmake ../kdenlive-${pkgver} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIB_INSTALL_DIR=/usr/lib \
+    -DLINK_LIBRARIES=-lX11
+  make
+}
+
+package() {
+  cd "${srcdir}"/build
+  make DESTDIR="${pkgdir}" install
+}